%{

#include <stddef.h>

#include "conf-parser.h"

#include "networkd.h"

#include "net-util.h"

%}

struct ConfigPerfItem;

%null_strings

%language=ANSI-C

%define slot-name section_and_lvalue

%define hash-function-name network_gperf_hash

%define lookup-function-name network_gperf_lookup

%readonly-tables

%omit-struct-type

%struct-type

%includes

%%

Match.MACAddress, config_parse_hwaddr, 0, offsetof(Network, match_mac)

Match.Path, config_parse_string, 0, offsetof(Network, match_path)

Match.Driver, config_parse_string, 0, offsetof(Network, match_driver)

Match.Type, config_parse_string, 0, offsetof(Network, match_type)

Match.Name, config_parse_ifname, 0, offsetof(Network, match_name)

Match.Host, config_parse_net_condition, CONDITION_HOST, offsetof(Network, match_host)

Match.Virtualization, config_parse_net_condition, CONDITION_VIRTUALIZATION, offsetof(Network, match_virt)

Match.KernelCommandLine, config_parse_net_condition, CONDITION_KERNEL_COMMAND_LINE, offsetof(Network, match_kernel)

Network.Description, config_parse_string, 0, offsetof(Network, description)

Network.Bridge, config_parse_bridge, 0, offsetof(Network, bridge)

Network.Bond, config_parse_bond, 0, offsetof(Network, bond)

Network.VLAN, config_parse_vlan, 0, offsetof(Network, vlans)

Network.DHCP, config_parse_bool, 0, offsetof(Network, dhcp)

Network.Address, config_parse_address, 0, 0

Network.Gateway, config_parse_gateway, 0, 0

Network.DNS, config_parse_dns, 0, offsetof(Network, dns)

Address.Address, config_parse_address, 0, 0

Address.Broadcast, config_parse_broadcast, 0, 0

Address.Label, config_parse_label, 0, 0

Route.Gateway, config_parse_gateway, 0, 0

Route.Destination, config_parse_destination, 0, 0

DHCPv4.UseDNS, config_parse_bool, 0, offsetof(Network, dhcp_dns)

DHCPv4.UseMTU, config_parse_bool, 0, offsetof(Network, dhcp_mtu)

DHCPv4.UseHostname, config_parse_bool, 0, offsetof(Network, dhcp_hostname)

DHCPv4.UseDomainName, config_parse_bool, 0, offsetof(Network, dhcp_domainname)

DHCPv4.CriticalConnection, config_parse_bool, 0, offsetof(Network, dhcp_critical)

NetDev.Description, config_parse_string, 0, offsetof(NetDev, description)

NetDev.Name, config_parse_ifname, 0, offsetof(NetDev, name)

NetDev.Kind, config_parse_netdev_kind, 0, offsetof(NetDev, kind)

VLAN.Id, config_parse_uint64, 0, offsetof(NetDev, vlanid)