13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl Process this file with autoconf to produce a configure script.

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_PREREQ(2.53)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync# Always use 0.xx+devel instead of 0.xxdevel for the version, e.g. 0.46+devel.

1c94c0a63ba68be1a7b2c640e70d7a06464e4fcavboxsync# Rationale: (i) placate simple version comparison software such as

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsync# `dpkg --compare-versions'. (ii) We don't always know what the next

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsync# version is going to be called until about the time we release it

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsync# (whereas we always know what the previous version was called).

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsyncAC_INIT(inkscape, 0.47+devel)

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsync

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsyncAC_CANONICAL_HOST

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsyncAC_CONFIG_SRCDIR([src/main.cpp])

a16eb14ad7a4b5ef91ddc22d3e8e92d930f736fcvboxsyncAM_INIT_AUTOMAKE([dist-zip dist-bzip2 tar-pax])

565c6b62913edd14704b060e3172bba10b1fe12evboxsync

1c94c0a63ba68be1a7b2c640e70d7a06464e4fcavboxsyncAC_ARG_ENABLE([lsb], AS_HELP_STRING([--enable-lsb], [LSB-compatible build configuration]), [

1c94c0a63ba68be1a7b2c640e70d7a06464e4fcavboxsync prefix=/opt/inkscape

1c94c0a63ba68be1a7b2c640e70d7a06464e4fcavboxsync PATH="/opt/lsb/bin:$PATH"

1c94c0a63ba68be1a7b2c640e70d7a06464e4fcavboxsync CC=lsbcc

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync CXX=lsbc++

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync export CC CXX

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync])

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAM_CONFIG_HEADER(config.h)

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncAC_LANG(C++)

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncAC_ISC_POSIX

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncAC_PROG_CXX

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncAM_PROG_CC_STDC

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncAM_PROG_AS

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAC_PROG_RANLIB

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAC_PROG_INTLTOOL(0.22)

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAC_HEADER_STDC

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncINK_BZR_SNAPSHOT_BUILD

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncdnl If automake 1.11 shave the output to look nice

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncm4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncdnl These next few lines are needed only while libcroco is in our source tree.

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAC_PROG_CC

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsyncAM_PROG_CC_C_O

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsyncif test "$GCC" = "yes"; then

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # Enable some warnings from gcc.

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync AC_LANG_PUSH(C)

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync ####

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync # Generic cpp flags...

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # What is just plain "-W" ?

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # Fortify source requires -O2 or higher, which is handled with newer autoconf

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync CPPFLAGS="-W -D_FORTIFY_SOURCE=2 $CPPFLAGS"

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # Enable format and format security warnings

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync CPPFLAGS="-Wformat -Wformat-security $CPPFLAGS"

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # Enable all default warnings

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync CPPFLAGS="-Wall $CPPFLAGS"

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync # Test for -Werror=... (introduced some time post-4.0)

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync # If we hit a format error -- it should be fatal.

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync AC_MSG_CHECKING([compiler support for -Werror=format-security])

3dc9141e9dc45634498a9b543477bec0bcf5dab8vboxsync ink_svd_CPPFLAGS="$CPPFLAGS"

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync CPPFLAGS="-Werror=format-security $CPPFLAGS"

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])

66cd15f94910b1afc64c42375d40e01d5d33ad2fvboxsync AC_MSG_RESULT([$ink_opt_ok])

fa8e26644bdce3fe8590a2fd82433dc8bdf55414vboxsync if test "x$ink_opt_ok" != "xyes"; then

fa8e26644bdce3fe8590a2fd82433dc8bdf55414vboxsync CPPFLAGS="$ink_svd_CPPFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync fi

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync ####

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync # C-specific flags...

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync # -Wno-pointer-sign is probably new in gcc 4.0; certainly it isn't accepted

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync # by gcc 2.95.

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_CHECKING([compiler support for -Wno-pointer-sign])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync ink_svd_CFLAGS="$CFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync CFLAGS="-Wno-pointer-sign $CFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_COMPILE_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])

7ca4727ba2f9e3703771a308b11cd551f3fca4fdvboxsync AC_MSG_RESULT([$ink_opt_ok])

7ca4727ba2f9e3703771a308b11cd551f3fca4fdvboxsync if test "x$ink_opt_ok" != "xyes"; then

2043260aa6abeee8eb8cf0309cebb97ede45851evboxsync CFLAGS="$ink_svd_CFLAGS"

2043260aa6abeee8eb8cf0309cebb97ede45851evboxsync fi

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync ####

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync # Linker flags...

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync # Have linker produce read-only relocations, if it knows how

2043260aa6abeee8eb8cf0309cebb97ede45851evboxsync AC_MSG_CHECKING([linker tolerates -z relro])

e7aa635d70dd0cdf083287ec896fe8cca2775466vboxsync ink_svd_LDFLAGS="$LDFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync LDFLAGS="-Wl,-z,relro $LDFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_LINK_IFELSE(AC_LANG_PROGRAM([]), [ink_opt_ok=yes], [ink_opt_ok=no])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_RESULT([$ink_opt_ok])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync if test "x$ink_opt_ok" != "xyes"; then

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync LDFLAGS="$ink_svd_LDFLAGS"

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync fi

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync AC_LANG_POP

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

6ba8963f8a097b33938cd6fbcd6b63faf6d26889vboxsync # C++-specific flags are defined further below. Look for CXXFLAGS...

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncfi

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncdnl Honor aclocal flags

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncACLOCAL="$ACLOCAL $ACLOCAL_FLAGS"

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncdnl Verify our GCC version

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncif test "x$GXX" = "xyes"; then

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync AC_MSG_CHECKING([GNU compiler version])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync # Don't pass CXXFLAGS to the following CXX command as some

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync # of them can't be specified along with '-v'.

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync cc_version=["`$CXX -v 2>&1 </dev/null |grep 'gcc version' |\

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync sed 's/.*gcc version \([-a-z0-9\.]*\).*/\1/'`"]

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync AC_MSG_RESULT([$cc_version])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync # Some version numbers

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync cc_vers_major=`echo $cc_version | cut -f1 -d.`

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync cc_vers_minor=`echo $cc_version | cut -f2 -d.`

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync cc_vers_patch=`echo $cc_version | cut -f3 -d.`

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync test -n "$cc_vers_major" || cc_vers_major=0

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync test -n "$cc_vers_minor" || cc_vers_minor=0

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync test -n "$cc_vers_patch" || cc_vers_patch=0

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync cc_vers_all=`expr $cc_vers_major '*' 1000000 + $cc_vers_minor '*' 1000 + $cc_vers_patch`

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync if test $cc_vers_major -lt 3; then

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_ERROR([gcc >= 3.0 is needed to compile inkscape])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync fi

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncfi

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync# Detect a working version of unordered containers.

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncAC_MSG_CHECKING([TR1 unordered_set usability])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncAC_COMPILE_IFELSE([

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync#include <tr1/unordered_set>

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncint main() {

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync std::tr1::unordered_set<int> i, j;

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync i = j;

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync return 0;

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync}

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync], [unordered_set_works=yes], [unordered_set_works=no])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncif test "x$unordered_set_works" = "xyes"; then

df409c2a6d13641b0586a36103d015cc8d76da53vboxsync AC_MSG_RESULT([ok])

df409c2a6d13641b0586a36103d015cc8d76da53vboxsync AC_DEFINE(HAVE_TR1_UNORDERED_SET, 1, [Has working standard TR1 unordered_set])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncelse

df409c2a6d13641b0586a36103d015cc8d76da53vboxsync AC_MSG_RESULT([not working])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncfi

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_CHECK_HEADER([boost/unordered_set.hpp], [AC_DEFINE(HAVE_BOOST_UNORDERED_SET, 1, [Boost unordered_set (Boost >= 1.36)])], [])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncAC_CHECK_HEADER([ext/hash_set], [AC_DEFINE(HAVE_EXT_HASH_SET, 1, [Legacy GNU ext/hash_set])], [])

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync# Test whether GCC emits a spurious warning when using boost::optional

df409c2a6d13641b0586a36103d015cc8d76da53vboxsync# If yes, turn off strict aliasing warnings to reduce noise

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync# and allow the legitimate warnings to stand out

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncAC_MSG_CHECKING([for overzealous strict aliasing warnings])

df409c2a6d13641b0586a36103d015cc8d76da53vboxsyncignore_strict_aliasing=no

e4d40e67c9cbfecb0b2ed48eec081648ba3a14bavboxsyncCXXFLAGS_SAVE=$CXXFLAGS

df409c2a6d13641b0586a36103d015cc8d76da53vboxsyncCXXFLAGS="$CXXFLAGS -Werror=strict-aliasing"

df409c2a6d13641b0586a36103d015cc8d76da53vboxsyncAC_COMPILE_IFELSE([

df409c2a6d13641b0586a36103d015cc8d76da53vboxsync#include <boost/optional.hpp>

df409c2a6d13641b0586a36103d015cc8d76da53vboxsyncboost::optional<int> x;

9868c07279330f31ed91aa986bec707b7e8635a3vboxsyncint func() {

9868c07279330f31ed91aa986bec707b7e8635a3vboxsync return *x;

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync}

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync], [ignore_strict_aliasing=no], [ignore_strict_aliasing=yes])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_MSG_RESULT($ignore_strict_aliasing)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncCXXFLAGS=$CXXFLAGS_SAVE

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncif test "x$ignore_strict_aliasing" = "xyes"; then

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync CXXFLAGS="$CXXFLAGS -Wno-strict-aliasing"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncfi

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl ******************************

b1ae8b1c40ec6bb82e7984b72712df5661332e2cvboxsyncdnl Gettext stuff

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl ******************************

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncGETTEXT_PACKAGE="AC_PACKAGE_NAME"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_SUBST(GETTEXT_PACKAGE)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE",[Translation domain used])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl Add the languages which your application supports here.

6e9e03fceb2e76b576905c4d3faa55ca31555956vboxsyncALL_LINGUAS="am ar az be bg bn br ca ca@valencia cs da de dz el en_AU en_CA en_GB en_US@piglatin eo es_MX es et eu fa fi fr ga gl he hr hu hy id it ja km ko lt mk mn nb ne nl nn pa pl pt_BR pt ro ru rw sk sl sq sr@latin sr sv th tr uk vi zh_CN zh_TW"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAM_GLIB_GNU_GETTEXT

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_PATH_PROG(PKG_CONFIG, pkg-config, no)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncif test "x$PKG_CONFIG" = "xno"; then

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_ERROR(You have to install pkg-config to compile inkscape.)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncfi

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsync

a4ab203fe0f52099fa53f52758e83d06f470ac04vboxsyncdnl Find msgfmt. Without this, po/Makefile fails to set MSGFMT on some platforms.

74959ba85f2898a152aed46b41cfe908638f2420vboxsyncAC_PATH_PROG(MSGFMT, msgfmt, msgfmt)

74959ba85f2898a152aed46b41cfe908638f2420vboxsyncAC_PATH_PROG(GMSGFMT, gmsgfmt, $MSGFMT)

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsync

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsyncdnl ******************************

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsyncdnl Check for OpenMP

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsyncdnl Replace this with AC_OPENMP once Autoconf 2.62 is widespread

d2c66e0925a76b3636d86b2afb2487fd6f956aebvboxsyncdnl ******************************

e62e26b69d90d1f29ad146c68606d95cf47340a4vboxsyncAX_OPENMP([openmp_ok=yes],[openmp_ok=no])

2043260aa6abeee8eb8cf0309cebb97ede45851evboxsyncif test "x$openmp_ok" = "xyes"; then

2043260aa6abeee8eb8cf0309cebb97ede45851evboxsync dnl We have it, now set up the flags

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync CXXFLAGS="$CXXFLAGS $OPENMP_CXXFLAGS"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_CHECK_HEADER(omp.h)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncfi

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl ******************************

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl Check for libpng

0fd850701c4b07dd4cc9074734b8d98f6184055cvboxsyncdnl ******************************

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_CHECK_LIB(png, png_read_info, [AC_CHECK_HEADER(png.h, png_ok=yes, png_ok=yes)], png_ok=no, -lz -lm)

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncif test "x$png_ok" != "xyes"; then

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_ERROR([libpng >= 1.2 is needed to compile inkscape])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncfi

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl Handle possible dlopen requirement for libgc

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncdnl Isn't this internal to something in autoconf? Couldn't find it...

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncAC_CHECK_LIB([dld], [shl_load], [lt_cv_dlopen="shl_load" lt_cv_dlopen_libs="-dld"], [AC_CHECK_FUNC([dlopen],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [lt_cv_dlopen="dlopen"],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [AC_CHECK_LIB([dl], [dlopen],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-ldl"],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [AC_CHECK_LIB([svld], [dlopen],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [lt_cv_dlopen="dlopen" lt_cv_dlopen_libs="-lsvld"],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [AC_CHECK_LIB([dld], [dld_link],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [lt_cv_dlopen="dld_link" lt_cv_dlopen_libs="-dld"])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync ])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync ])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync ])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync ])

6a4586a1a79ef87a9b97119ae350009a258fe924vboxsync

6a4586a1a79ef87a9b97119ae350009a258fe924vboxsyncAC_CHECK_HEADERS([gc.h gc/gc.h],

b1fd0840de05fc2e189d4ea55ba33c2d6b09a4d8vboxsync [

b1fd0840de05fc2e189d4ea55ba33c2d6b09a4d8vboxsync # To test for the different required libs, I have to

b1fd0840de05fc2e189d4ea55ba33c2d6b09a4d8vboxsync # overcome autoconf's caching system, so I change the

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync # desired function name. They're all in libgc.

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync # The "break" will exit from the top level

6a4586a1a79ef87a9b97119ae350009a258fe924vboxsync # AC_CHECK_HEADERS.

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync gc_libs=""

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync AC_CHECK_LIB(gc, GC_init,

b1fd0840de05fc2e189d4ea55ba33c2d6b09a4d8vboxsync [gc_ok=yes;

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync LIBS="-lgc $gc_libs $LIBS";

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync break], [gc_ok=no], [$gc_libs])

6a4586a1a79ef87a9b97119ae350009a258fe924vboxsync gc_libs="-lpthread"

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync AC_CHECK_LIB(gc, GC_malloc,

7a006aff4af0ac1eaed18e272ecc9aeeaf41e4efvboxsync [gc_ok=yes;

b1fd0840de05fc2e189d4ea55ba33c2d6b09a4d8vboxsync LIBS="-lgc $gc_libs $LIBS";

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync break], [gc_ok=no], [$gc_libs])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync gc_libs="$lt_cv_dlopen_libs"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_CHECK_LIB(gc, GC_realloc,

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [gc_ok=yes;

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync LIBS="-lgc $gc_libs $LIBS";

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync break], [gc_ok=no], [$gc_libs])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync gc_libs="-lpthread $lt_cv_dlopen_libs"

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_CHECK_LIB(gc, GC_free,

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [gc_ok=yes;

b1ae8b1c40ec6bb82e7984b72712df5661332e2cvboxsync LIBS="-lgc $gc_libs $LIBS";

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync break], [gc_ok=no], [$gc_libs])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync break],

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync [gc_ok=no])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsyncif test "x$gc_ok" = "xyes" && test "x$cross_compiling" = "xno" ; then

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_MSG_CHECKING([libgc version 6.4+])

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync AC_RUN_IFELSE(

6831f283dbc5c27bde8a8f8bea179b84a5741697vboxsync [AC_LANG_SOURCE([[

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync #ifdef HAVE_GC_GC_H

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync # include <gc/gc.h>

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync #else

01ea175f55740168d1dd0af3277d3b86a30b4f91vboxsync # include <gc.h>

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync #endif

13fdd42f1fc3e519650037a920e6a54c24973866vboxsync #include <stdio.h>

01ea175f55740168d1dd0af3277d3b86a30b4f91vboxsync extern unsigned GC_version;

int main(void){

unsigned min = ((6 << 16) | (4 << 8) | 0);

printf("%d.%d.%d ",GC_version >> 16, (GC_version >> 8) & 0xFF, GC_version & 0xFF);

if (GC_version>=min) return 0;

return 1;

}]])],

[gc_ok=yes],

[gc_ok=no]

)

AC_MSG_RESULT([$gc_ok])

fi

if test "x$gc_ok" != "xyes"; then

AC_MSG_ERROR([libgc (the Boehm Conservative Collector) 6.4+, is needed to compile inkscape -- http://www.hpl.hp.com/personal/Hans_Boehm/gc])

fi

dnl This check is to get a FIONREAD definition on Solaris 8

AC_CHECK_HEADERS([sys/filio.h])

AC_CHECK_HEADERS([malloc.h])

AC_CHECK_FUNCS([mallinfo], [

AC_CHECK_MEMBERS([struct mallinfo.usmblks,

struct mallinfo.fsmblks,

struct mallinfo.uordblks,

struct mallinfo.fordblks,

struct mallinfo.hblkhd],,,

[#include <malloc.h>])

])

AC_PATH_PROG(FREETYPE_CONFIG, freetype-config, no)

if test "x$FREETYPE_CONFIG" = "xno"; then

AC_MSG_ERROR([Cannot find freetype-config])

fi

FREETYPE_CFLAGS=`$FREETYPE_CONFIG --cflags`

FREETYPE_LIBS=`$FREETYPE_CONFIG --libs`

AC_SUBST(FREETYPE_CFLAGS)

AC_SUBST(FREETYPE_LIBS)

dnl ******************************

dnl Win32

dnl ******************************

AC_MSG_CHECKING([for Win32 platform])

case "$host" in

*-*-mingw*)

platform_win32=yes

WIN32_CFLAGS="-mms-bitfields -DLIBXML_STATIC"

;;

*)

platform_win32=no

;;

esac

AC_MSG_RESULT([$platform_win32])

AM_CONDITIONAL(PLATFORM_WIN32, test "$platform_win32" = "yes")

AC_SUBST(WIN32_CFLAGS)

AC_MSG_CHECKING([for Solaris platform])

case "$host" in

*-solaris2.*)

platform_solaris=yes

solaris_version=`echo $host|sed -e 's/^.*-solaris2\.//' -e s'/\..*$//'`

CFLAGS="$CFLAGS -DSOLARIS=$solaris_version"

CXXFLAGS="$CXXFLAGS -DSOLARIS=$solaris_version"

;;

*)

platform_solaris=no

;;

esac

AC_MSG_RESULT([$platform_solaris])

AM_CONDITIONAL(PLATFORM_SOLARIS, test "$platform_solaris" = "yes")

dnl ******************************

dnl Xft checking

dnl ******************************

AC_ARG_WITH(xft,

AC_HELP_STRING([--with-xft], [use xft scalable font database (default is auto)]),

[with_xft=$withval], [with_xft=auto])

if test "x$with_xft" != "xno" ; then

dnl Test fontconfig package

PKG_CHECK_MODULES(XFT, fontconfig, xft_ok=yes, xft_ok=no)

if test "x$xft_ok" != "xyes"; then

dnl test xft package

PKG_CHECK_MODULES(XFT, xft, xft_ok=yes, xft_ok=no)

if test "x$xft_ok" != "xyes"; then

dnl Have to test xft presence

AC_CHECK_HEADER(X11/Xft/Xft.h, xft_ok=yes, xft_ok=no)

if test "x$xft_ok" != "xyes"; then

dnl No xft found

if test "x$with_xft" = "xyes"; then

dnl Xft was explicitly asked, so stop

AC_MSG_ERROR([--with-xft was specified, but appropriate development packages could not be found])

fi

else

dnl Working Xft1

XFT_LIBS="-L/usr/X11R6/lib -lXft "

fi

fi

fi

else

dnl Asked to ignore xft

xft_ok=no

fi

AC_SUBST(XFT_CFLAGS)

AC_SUBST(XFT_LIBS)

AM_CONDITIONAL(USE_XFT, test "x$xft_ok" = "xyes")

if test "x$xft_ok" = "xyes"; then

AC_DEFINE(WITH_XFT, 1, [Use Xft font database])

fi

dnl ******************************

dnl pangoft2 for xft

dnl ******************************

if test "x$xft_ok" = "xyes"; then

PKG_CHECK_MODULES(PANGOFT2, pangoft2, pango_ok=yes, pango_ok=no)

if test "x$pango_ok" = "xyes"; then

XFT_LIBS="$XFT_LIBS $PANGOFT2_LIBS"

fi

fi

dnl ******************************

dnl gnome vfs checking

dnl ******************************

AC_ARG_WITH(gnome-vfs,

AC_HELP_STRING([--with-gnome-vfs], [use gnome vfs for loading files]),

[with_gnome_vfs=$withval], [with_gnome_vfs=auto])

if test "x$with_gnome_vfs" = "xno"; then

dnl Asked to ignore gnome-vfs

gnome_vfs=no

else

dnl Have to test gnome-vfs presence

PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0 >= 2.0, gnome_vfs=yes, gnome_vfs=no)

if test "x$gnome_vfs" != "xyes"; then

dnl No gnome-vfs found

if test "x$with_gnome_vfs" = "xyes"; then

dnl Gnome-VFS was explicitly asked for, so stop

AC_MSG_ERROR([--with-gnome-vfs was specified, but appropriate libgnomevfs development packages could not be found])

else

# gnome-vfs is no, tell us for the log file

AC_MSG_RESULT($gnome_vfs)

fi

fi

fi

AM_CONDITIONAL(USE_GNOME_VFS, test "x$gnome_vfs" = "xyes")

if test "x$gnome_vfs" = "xyes"; then

AC_DEFINE(WITH_GNOME_VFS, 1, [Use gnome vfs file load functionality])

fi

AC_SUBST(GNOME_VFS_CFLAGS)

AC_SUBST(GNOME_VFS_LIBS)

dnl ******************************

dnl libinkjar checking

dnl ******************************

AC_ARG_WITH(inkjar,

AC_HELP_STRING([--without-inkjar], [disable openoffice files (SVG jars)]),[with_ij=$withval], [with_ij=yes])

if test "x$with_ij" = "xyes"; then

AC_DEFINE(WITH_INKJAR, 1, [enable openoffice files (SVG jars)])

AC_C_BIGENDIAN

AC_CHECK_HEADERS(zlib.h)

ij=yes

else

ij=no

fi

AM_CONDITIONAL(INKJAR, test "$with_ij" = "yes")

ink_spell_pkg=

if pkg-config --exists gtkspell-2.0; then

ink_spell_pkg=gtkspell-2.0

AC_DEFINE(WITH_GTKSPELL, 1, [enable gtk spelling widget])

fi

dnl ******************************

dnl PERL checking

dnl ******************************

AC_MSG_CHECKING(for Perl development environment)

AC_ARG_WITH(perl,

AC_HELP_STRING([--with-perl], [use Perl for embedded scripting (EXPERIMENTAL)]),

[with_perl=$withval], [with_perl=skipped])

if test "x$with_perl" = "xyes"; then

checkPERL_CFLAGS=`perl -MExtUtils::Embed -e perl_inc 2>/dev/null`

if test "$?" -gt "0"; then

with_perl="no"

else

checkPERL_LIBS=`perl -MExtUtils::Embed -e ldopts 2>/dev/null`

if test "$?" -gt "0"; then

with_perl="no"

else

with_perl="yes"

fi

fi

fi

AC_MSG_RESULT([$with_perl])

if test "x$with_perl" = "xyes"; then

# Test that we actually have the perl libraries installed

oldCFLAGS="$CFLAGS"

oldLIBS="$LIBS"

CFLAGS="$CFLAGS $checkPERL_CFLAGS"

LIBS="$LIBS $checkPERL_LIBS"

AC_CHECK_FUNC([perl_parse],[

PERL_CFLAGS="$checkPERL_CFLAGS"

PERL_LIBS="$checkPERL_LIBS"

AC_DEFINE(WITH_PERL, 1, [use Perl for embedded scripting])

],[

with_perl="no"

])

CFLAGS="$oldCFLAGS"

LIBS="$oldLIBS"

fi

AM_CONDITIONAL(WITH_PERL, test "x$with_perl" = "xyes")

AC_SUBST(PERL_CFLAGS)

AC_SUBST(PERL_LIBS)

dnl ******************************

dnl Python checking

dnl ******************************

AC_MSG_CHECKING(for Python development environment)

AC_ARG_WITH(python,

AC_HELP_STRING([--with-python], [use Python for embedded scripting (EXPERIMENTAL)]),

[with_python=$withval], [with_python=skipped])

if test "x$with_python" = "xyes"; then

checkPYTHON_CFLAGS=`python -c "import distutils.sysconfig ; print '-I%s' % distutils.sysconfig.get_config_var('INCLUDEPY')" 2>/dev/null`

if test "$?" -gt "0"; then

with_python="no"

else

checkPYTHON_LIBS=`python -c "import distutils.sysconfig ; print '%s/%s %s' % (distutils.sysconfig.get_config_var('LIBPL'),distutils.sysconfig.get_config_var('LDLIBRARY'),distutils.sysconfig.get_config_var('LIBS'))" 2>/dev/null`

if test "$?" -gt "0"; then

with_python="no"

else

with_python="yes"

fi

fi

fi

AC_MSG_RESULT([$with_python])

if test "x$with_python" = "xyes"; then

# Test that we actually have the python libraries installed

oldCFLAGS="$CFLAGS"

oldLIBS="$LIBS"

CFLAGS="$CFLAGS $checkPYTHON_CFLAGS"

LIBS="$LIBS $checkPYTHON_LIBS"

AC_CHECK_FUNC([Py_Initialize],[

PYTHON_CFLAGS="$checkPYTHON_CFLAGS"

PYTHON_LIBS="$checkPYTHON_LIBS"

AC_DEFINE(WITH_PYTHON, 1, [use Python for embedded scripting])

],[

with_python="no"

])

CFLAGS="$oldCFLAGS"

LIBS="$oldLIBS"

fi

AM_CONDITIONAL(WITH_PYTHON, test "x$with_python" = "xyes")

AC_SUBST(PYTHON_CFLAGS)

AC_SUBST(PYTHON_LIBS)

dnl ******************************

dnl LittleCms checking

dnl ******************************

AC_ARG_ENABLE(lcms,

AC_HELP_STRING([--enable-lcms], [enable LittleCms for color management]),

[enable_lcms=$enableval], [enable_lcms=yes])

if test "x$enable_lcms" = "xno"; then

dnl Asked to ignore LittleCms

lcms=no

else

dnl Have to test LittleCms presence

PKG_CHECK_MODULES(LCMS, lcms >= 1.13, lcms=yes, lcms=no)

if test "x$lcms" != "xyes"; then

dnl No lcms found

if test "x$enable_lcms" = "xyes"; then

dnl LittleCms was explicitly asked for, so stop

AC_MSG_ERROR([--enable-lcms was specified, but appropriate LittleCms development packages could not be found])

else

# lcms is no, tell us for the log file

AC_MSG_RESULT($lcms)

fi

else

dnl Working lcms

LIBS="$LIBS $LCMS_LIBS"

AC_DEFINE(ENABLE_LCMS, 1, [Use LittleCms color management])

fi

fi

AC_SUBST(LCMS_CFLAGS)

AC_SUBST(LCMS_LIBS)

dnl ******************************

dnl Libpoppler checking

dnl ******************************

AC_ARG_ENABLE(poppler-cairo,

AC_HELP_STRING([--enable-poppler-cairo], [Enable libpoppler-cairo for rendering PDF preview]),

[enable_poppler_cairo=$enableval], [enable_poppler_cairo=yes])

POPPLER_CFLAGS=""

PKG_CHECK_MODULES(POPPLER, poppler >= 0.5.9, poppler=yes, poppler=no)

if test "x$poppler" = "xyes"; then

dnl Working libpoppler

dnl Have to test libpoppler-glib presence

PKG_CHECK_MODULES(POPPLER_GLIB, poppler-glib >= 0.5.9, poppler_glib=yes, poppler_glib=no)

if test "x$poppler_glib" = "xyes"; then

dnl Working libpoppler-glib found

dnl Check whether the Cairo SVG backend is available

PKG_CHECK_MODULES(CAIRO_SVG, cairo-svg, cairo_svg=yes, cairo_svg=no)

if test "x$cairo_svg" = "xyes"; then

POPPLER_LIBS="$POPPLER_LIBS $POPPLER_GLIB_LIBS "

fi

fi

if test "x$enable_poppler_cairo" = "xyes"; then

dnl Have to test libpoppler-cairo presence for PDF preview

dnl AC_CHECK_HEADER(Magick++.h, magick_ok=yes, magick_ok=no)

PKG_CHECK_MODULES(POPPLER_CAIRO, poppler-cairo >= 0.5.9, poppler_cairo=yes, poppler_cairo=no)

if test "x$poppler_glib" = "xyes" -a "x$poppler_cairo" = "xyes" -a \

"x$cairo_svg" = "xno"

then

POPPLER_LIBS="$POPPLER_LIBS $POPPLER_CAIRO_LIBS "

fi

fi

fi

if test "x$poppler" = "xyes"; then

LIBS="$LIBS $POPPLER_LIBS"

AC_DEFINE(HAVE_POPPLER, 1, [Use libpoppler for direct PDF import])

fi

if test "x$poppler_cairo" = "xyes" -a "x$poppler_glib" = "xyes"; then

AC_DEFINE(HAVE_POPPLER_CAIRO, 1, [Use libpoppler-cairo for rendering PDF preview])

fi

if test "x$poppler_glib" = "xyes" -a "x$cairo_svg" = "xyes"; then

AC_DEFINE(HAVE_POPPLER_GLIB, 1, [Use libpoppler-glib and Cairo-SVG for PDF import])

fi

AC_SUBST(POPPLER_CFLAGS)

AC_SUBST(POPPLER_LIBS)

PKG_CHECK_MODULES(POPPLER_GFXFONT, poppler >= 0.8.3, popplernew=yes, popplernew=no)

if test "x$popplernew" = "xyes"; then

AC_DEFINE(POPPLER_NEW_GFXFONT, 1, [Use GfxFont from Poppler >= 0.8.3])

fi

AC_MSG_CHECKING(for new color space API in Poppler)

ink_svd_CPPFLAGS=$CPPFLAGS

ink_svd_LIBS=$LIBS

CPPFLAGS="$CPPFLAGS $POPPLER_CFLAGS"

LIBS="$LIBS $POPPLER_LIBS"

popplercolor="no"

AC_COMPILE_IFELSE([

#include <GfxState.h>

int main() {

typedef GfxColorSpace *(*parse_p)(Object *, Gfx *);

parse_p p;

p = &GfxColorSpace::parse;

return 0;

}

], [popplercolor=yes])

CPPFLAGS=$ink_svd_CPPFLAGS

LIBS=$ink_svd_LIBS

if test "x$popplercolor" = "xyes"; then

AC_DEFINE(POPPLER_NEW_COLOR_SPACE_API, 1, [Use color space API from Poppler >= 0.12.2])

AC_MSG_RESULT(yes)

else

AC_MSG_RESULT(no)

fi

dnl ******************************

dnl Inkboard dependency checking

dnl ******************************

dnl with_inkboard="no"

dnl with_inkboard_ssl="no"

dnl INKBOARD_CFLAGS=""

dnl AC_ARG_ENABLE(inkboard,

dnl AS_HELP_STRING([--enable-inkboard], [enable Inkboard online whiteboard facility (disabled by default)]),

dnl with_inkboard=$enableval,with_inkboard=no)

dnl if test "x$with_inkboard" = "xyes"; then

dnl with_inkboard="yes"

dnl AC_DEFINE(WITH_INKBOARD,1,[Build in Inkboard support])

dnl Test for OpenSSL

dnl PKG_CHECK_MODULES(INKBOARD, openssl, with_inkboard_ssl=yes, with_inkboard_ssl=no)

dnl if test "x$with_inkboard_ssl" = "xyes"; then

dnl OpenSSL found; enable SSL support in Pedro

dnl INKBOARD_CFLAGS="$INKBOARD_CFLAGS -DHAVE_SSL"

dnl RELAYTOOL([ssl], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])

dnl RELAYTOOL([crypto], INKBOARD_LIBS, INKBOARD_CFLAGS, [inkboard_weak=yes])

dnl AC_DEFINE(WITH_INKBOARD_SSL,1,[Build in SSL support for Inkboard])

dnl fi

dnl else

dnl with_inkboard="no"

dnl fi

dnl AM_CONDITIONAL(WITH_INKBOARD, test "x$with_inkboard" = "xyes")

INKBOARD_CFLAGS=""

INKBOARD_LIBS=""

AC_SUBST(INKBOARD_LIBS)

AC_SUBST(INKBOARD_CFLAGS)

dnl ******************************

dnl Check for libwpg for extension

dnl ******************************

PKG_CHECK_MODULES(LIBWPG, libwpg-0.1 libwpg-stream-0.1, with_libwpg=yes, with_libwpg=no)

if test "x$with_libwpg" = "xyes"; then

AC_DEFINE(WITH_LIBWPG,1,[Build in libwpg])

fi

AM_CONDITIONAL(WITH_LIBWPG, test "x$with_libwpg" = "xyes")

AC_SUBST(LIBWPG_LIBS)

AC_SUBST(LIBWPG_CFLAGS)

dnl ******************************

dnl Check for ImageMagick Magick++

dnl ******************************

PKG_CHECK_MODULES(IMAGEMAGICK, ImageMagick++, magick_ok=yes, magick_ok=no)

if test "x$magick_ok" = "xyes"; then

AC_DEFINE(WITH_IMAGE_MAGICK,1,[Image Magick++ support for bitmap effects])

fi

AM_CONDITIONAL(USE_IMAGE_MAGICK, test "x$magick_ok" = "xyes")

AC_SUBST(IMAGEMAGICK_LIBS)

AC_SUBST(IMAGEMAGICK_CFLAGS)

dnl ***********************************************************************************************************

dnl Check for a Cairo version that implements user-fonts feature (with a stable API, that is cairo > 1.7.6),

dnl so that we conditionally add SVGFonts support

dnl ***********************************************************************************************************

PKG_CHECK_MODULES(CAIRO_USER_FONTS, cairo > 1.7.6, cairouserfonts=yes, cairouserfonts=no)

if test "x$cairouserfonts" = "xyes"; then

AC_DEFINE(ENABLE_SVG_FONTS, 1, [SVG Fonts should be used])

fi

dnl ******************************

dnl Unconditional dependencies

dnl ******************************

dnl sigc++-2.0 >= 2.0.12: using "visit_each" not available in 2.0.10

if test $cc_vers_major -gt 3; then

min_sigc_version=2.0.12

else

min_sigc_version=2.0.11

fi

PKG_CHECK_MODULES(INKSCAPE, gdkmm-2.4 glibmm-2.4 giomm-2.4 gtkmm-2.4 >= 2.10.0 gtk+-2.0 libxml-2.0 >= 2.6.11 libxslt >= 1.0.15 cairo sigc++-2.0 >= $min_sigc_version $ink_spell_pkg gthread-2.0 >= 2.0 libpng >= 1.2 gsl)

# Check for Apple Mac OS X Carbon framework

carbon_ok=no

AC_MSG_CHECKING([for Mac OS X Carbon support])

AC_COMPILE_IFELSE([

#include <Carbon/Carbon.h>

#include <CoreServices/CoreServices.h>

], [carbon_ok=yes])

AC_MSG_RESULT($carbon_ok)

if test "x$carbon_ok" = "xyes"; then

AC_DEFINE(HAVE_CARBON, 1, [define to 1 if Carbon is available])

CARBON_LDFLAGS="-framework Carbon"

AC_SUBST(CARBON_LDFLAGS)

fi

AM_CONDITIONAL(HAVE_CARBON, test "x$carbon_ok" = "xyes")

# Check for some boost header files

AC_CHECK_HEADERS([boost/concept_check.hpp], [], AC_MSG_ERROR([You need the boost package (e.g. libboost-dev)]))

PKG_CHECK_MODULES(CAIRO_PDF, cairo-pdf, cairo_pdf=yes, cairo_pdf=no)

if test "x$cairo_pdf" = "xyes"; then

AC_DEFINE(HAVE_CAIRO_PDF, 1, [Whether the Cairo PDF backend is available])

fi

dnl Shouldn't we test for libpng and libz?

if test "x$openmp_ok" = "xyes"; then

INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz -lgomp"

else

INKSCAPE_LIBS="$INKSCAPE_LIBS -lpng -lz"

fi

AC_CHECK_HEADER(popt.h,

[INKSCAPE_LIBS="$INKSCAPE_LIBS -lpopt"],

AC_MSG_ERROR([libpopt is required]))

dnl **************************

dnl Check for aspell

dnl ******************************

AC_CHECK_LIB(aspell, new_aspell_config, [AC_CHECK_HEADER(aspell.h, aspell_ok=yes, aspell_ok=no)], aspell_ok=no, -lz -lm)

if test "x$aspell_ok" = "xyes"; then

AC_DEFINE(HAVE_ASPELL, 1, [Use aspell for built-in spellchecker])

INKSCAPE_LIBS="$INKSCAPE_LIBS -laspell"

else

AC_MSG_CHECKING([Aspell not found, spell checker will be disabled])

fi

dnl Check for bind_textdomain_codeset, including -lintl if GLib brings it in.

sp_save_LIBS=$LIBS

LIBS="$LIBS $INKSCAPE_LIBS"

AC_CHECK_FUNCS(bind_textdomain_codeset)

dnl Check for gtk_window_fullscreen in gtk (>= 2.2)

AC_CHECK_FUNCS(gtk_window_set_default_icon_from_file)

AC_CHECK_FUNCS(gtk_window_fullscreen)

LIBS=$sp_save_LIBS

dnl Check for binary relocation support

dnl Hongli Lai <h.lai@chello.nl>

AC_ARG_ENABLE(binreloc,

[ --enable-binreloc compile with binary relocation support],

enable_binreloc=$enableval,enable_binreloc=no)

AC_MSG_CHECKING(whether binary relocation support should be enabled)

if test "$enable_binreloc" = "yes"; then

AC_MSG_RESULT(yes)

AC_MSG_CHECKING(for linker mappings at /proc/self/maps)

if test -e /proc/self/maps; then

AC_MSG_RESULT(yes)

else

AC_MSG_RESULT(no)

AC_MSG_ERROR(/proc/self/maps is not available. Binary relocation cannot be enabled.)

enable_binreloc="no"

fi

elif test "$enable_binreloc" = "auto"; then

AC_MSG_RESULT(yes when available)

AC_MSG_CHECKING(for linker mappings at /proc/self/maps)

if test -e /proc/self/maps; then

AC_MSG_RESULT(yes)

enable_binreloc=yes

AC_MSG_CHECKING(whether everything is installed to the same prefix)

if test "$bindir" = '${exec_prefix}/bin' -a "$sbindir" = '${exec_prefix}/sbin' -a \

"$datadir" = '${prefix}/share' -a "$libdir" = '${exec_prefix}/lib' -a \

"$libexecdir" = '${exec_prefix}/libexec' -a "$sysconfdir" = '${prefix}/etc'

then

AC_MSG_RESULT(yes)

else

AC_MSG_RESULT(no)

AC_MSG_NOTICE(Binary relocation support will be disabled.)

enable_binreloc=no

fi

else

AC_MSG_RESULT(no)

enable_binreloc=no

fi

elif test "$enable_binreloc" = "no"; then

AC_MSG_RESULT(no)

else

AC_MSG_RESULT([no (unknown value "$enable_binreloc")])

enable_binreloc=no

fi

AC_DEFINE(BR_PTHREADS,[0],[Use binreloc thread support?])

if test "$enable_binreloc" = "yes"; then

AC_DEFINE(ENABLE_BINRELOC,,[Use AutoPackage?])

fi

AC_ARG_ENABLE(osxapp,

[ --enable-osxapp compile with OSX .app data dir paths],

enable_osxapp=$enableval,enable_osxapp=no)

if test "$enable_osxapp" = "yes"; then

AC_DEFINE(ENABLE_OSX_APP_LOCATIONS,,[Build with OSX .app data dir paths?])

fi

dnl ******************************

dnl Reported by autoscan

dnl ******************************

AC_CHECK_FUNCS(pow)

# if we did not find pow(), see if it's in libm.

if test x"$ac_cv_func_pow" = x"no" ; then

AC_CHECK_LIB(m,pow)

fi

AC_CHECK_FUNCS(sqrt)

AC_CHECK_FUNCS(floor)

AC_CHECK_FUNCS(gettimeofday)

AC_CHECK_FUNCS(memmove)

AC_CHECK_FUNCS(memset)

AC_CHECK_FUNCS(mkdir)

AC_CHECK_FUNCS(strncasecmp)

AC_CHECK_FUNCS(strpbrk)

AC_CHECK_FUNCS(strrchr)

AC_CHECK_FUNCS(strspn)

AC_CHECK_FUNCS(strstr)

AC_CHECK_FUNCS(strtoul)

AC_CHECK_FUNCS(fpsetmask)

AC_CHECK_FUNCS(ecvt)

AC_CHECK_HEADERS(ieeefp.h)

AC_CHECK_HEADERS(fcntl.h)

AC_CHECK_HEADERS(libintl.h)

AC_CHECK_HEADERS(stddef.h)

AC_CHECK_HEADERS(sys/time.h)

AC_FUNC_STAT

AC_FUNC_STRFTIME

AC_FUNC_STRTOD

AC_HEADER_STAT

AC_HEADER_TIME

AC_STRUCT_TM

AC_TYPE_MODE_T

AC_TYPE_SIGNAL

dnl Work around broken gcc 3.3 (seen on OSX) where "ENABLE_NLS" isn't

dnl set correctly because the gettext function isn't noticed.

if test "$ac_cv_header_libintl_h" = "yes" &&

test "$ac_cv_func_bind_textdomain_codeset" = "yes" &&

test "$gt_cv_func_have_gettext" != "yes"; then

AC_DEFINE(ENABLE_NLS)

fi

dnl ******************************

dnl Compilation warnings

dnl ******************************

if test "$GXX" = "yes"; then

# Enable some warnings from g++.

# Rationale: a number of bugs in inkscape have been fixed by enabling g++

# warnings and addressing the produced warnings. Usually the committing

# developer is the best person to address the warnings.

ink_svd_CXXFLAGS="$CXXFLAGS"

CXXFLAGS="-Wno-unused-parameter $CXXFLAGS"

# -Wno-unused-parameter isn't accepted by gcc 2.95.

AC_COMPILE_IFELSE([int dummy;

], , CXXFLAGS="-Wno-unused $ink_svd_CXXFLAGS",)

# Note: At least one bug has been caught from unused parameter warnings,

# so it might be worth trying not to disable it.

# One way of selectively disabling the warnings (i.e. only where the

# programmer deliberately isn't using the parameter, e.g. for a callback)

# is to remove the parameter name (leaving just its type), as is done

# in src/seltrans.cpp:sp_seltrans_handle_event; this indicates that the

# programmer deliberately has an unused parameter (e.g. because it's used

# as a callback or similar function pointer use).

# Add even more stuff

CXXFLAGS="-Wpointer-arith -Wcast-align -Wsign-compare -Woverloaded-virtual -Wswitch $CXXFLAGS"

fi

dnl ******************************

dnl libinkscape

dnl ******************************

dnl

dnl AC_ARG_ENABLE(libinkscape, AC_HELP_STRING([--enable-libinkscape], [Compile dynamic library (experimental)]), [splib=$enableval], [splib=no])

dnl

dnl AM_CONDITIONAL(ENABLE_LIBINKSCAPE, test "x$splib" != "xno")

dnl

AC_SUBST(INKSCAPE_CFLAGS)

AC_SUBST(INKSCAPE_LIBS)

dnl Define our data paths for config.h

AC_DEFINE_DIR([INKSCAPE_DATADIR], [datadir], [Base data directory])

AC_DEFINE_DIR([PACKAGE_LOCALE_DIR], [localedir], [Locatization directory])

AC_CONFIG_FILES([

Makefile

src/2geom/makefile

share/icons/application/16x16/Makefile

share/icons/application/22x22/Makefile

share/icons/application/24x24/Makefile

share/icons/application/32x32/Makefile

share/icons/application/48x48/Makefile

share/icons/application/256x256/Makefile

inkview.1

])

AH_BOTTOM([

])

AC_OUTPUT

echo "

Configuration:

Source code location: ${srcdir}

Destination path prefix: ${prefix}

Compiler: ${CXX}

CPPFLAGS: ${CPPFLAGS}

CXXFLAGS: ${CXXFLAGS}

CFLAGS: ${CFLAGS}

LDFLAGS: ${LDFLAGS}

Use Xft font database: ${xft_ok}

Use gnome-vfs: ${gnome_vfs}

Use openoffice files: ${ij}

Use relocation support: ${enable_binreloc}

Internal Python: ${with_python}

Internal Perl: ${with_perl}

Enable LittleCms: ${enable_lcms}

Enable Poppler-Cairo: ${enable_poppler_cairo}

ImageMagick Magick++: ${magick_ok}

Libwpg: ${with_libwpg}

"