arcfour_crypt_amd64.s revision 55553f719b521a0bb4deab6efc944cd30c1a56aa
/
/
/
/
/ http://www.mozilla.org/MPL/
/
/ License.
/
/
/
/ Contributor(s):
/
/
.ident "%Z%%M% %I% %E% SMI"
/
/
/ AMD64. It has been lifted intact, except for minor interface
/ changes to get along with Solaris crypto common code (the parameter
/ order and the key struct element order are both different).
/ The key and key elements must be aligned.
/
/ Register Usage
/ rax data[x]
/ rbx ARG(len)
/ rcx key->i (aka x)
/ rdx key->j (aka y)
/ rsi ARG(in)
/ rdi ARG(out)
/ rbp key->arr (aka data or d)
/ rsp stack
/ r8 8 bytes of rc4 stream
/ r9 temp
/ r10-r15 unused
/
#include <sys/asm_linkage.h>
ENTRY_NP(arcfour_crypt)
/* EXPORT DELETE START */
/ load parameters
push %rbp
push %rbx
mov %rdi, %rbp / rbp = ARG(key)
/ rsi = ARG(in)
mov %rdx, %rdi / rdi = ARG(out)
mov %rcx, %rbx / rbx = ARG(len)
/ load key indices and key
mov 2048(%rbp), %rcx / rcx x = key->i
mov 2056(%rbp), %rdx / rdx y = key->j
/ rbp d = key->arr
inc %rcx / x++
and $255, %rcx / x &= 0xff
lea -8(%rbx,%rsi), %rbx / rbx = in+len-8
mov %rbx, %r9 / tmp = in+len-8
mov (%rbp,%rcx,8), %rax / tx = d[x]
cmp %rsi, %rbx / cmp in with in+len-8
jl .Lend / jump if (in+len-8 < in)
.Lstart:
add $8, %rsi / increment in
add $8, %rdi / increment out
/ generate the next 8 bytes of the rc4 stream into %r8
mov $8, %r11 / byte counter
1: add %al, %dl / y += tx
mov (%rbp,%rdx,8), %ebx / ty = d[y]
mov %ebx, (%rbp,%rcx,8) / d[x] = ty
add %al, %bl / val = ty + tx
mov %eax, (%rbp,%rdx,8) / d[y] = tx
inc %cl / x++ (NEXT ROUND)
mov (%rbp,%rcx,8), %eax / tx = d[x] (NEXT ROUND)
movb (%rbp,%rbx,8), %r8b / val = d[val]
dec %r11b
ror $8, %r8 / (ror does not change ZF)
jnz 1b
/ xor 8 bytes
xor -8(%rsi), %r8
cmp %r9, %rsi / cmp in+len-8 with in
mov %r8, -8(%rdi)
jle .Lstart / jump if (in <= in+len-8)
.Lend:
add $8, %r9 / tmp = in+len
/ handle the last bytes, one by one
1: cmp %rsi, %r9 / cmp in with in+len
jle .Lfinished / jump if (in+len <= in)
add %al, %dl / y += tx
mov (%rbp,%rdx,8), %ebx / ty = d[y]
mov %ebx, (%rbp,%rcx,8) / d[x] = ty
add %al, %bl / val = ty + tx
mov %eax, (%rbp,%rdx,8) / d[y] = tx
inc %cl / x++ (NEXT ROUND)
mov (%rbp,%rcx,8), %eax / tx = d[x] (NEXT ROUND)
movb (%rbp,%rbx,8), %r8b / val = d[val]
xor (%rsi), %r8b / xor 1 byte
movb %r8b, (%rdi)
inc %rsi / in++
inc %rdi / out++
jmp 1b
.Lfinished: / save key indices i & j
dec %rcx / x--
movb %dl, 2056(%rbp) / key->j = y
movb %cl, 2048(%rbp) / key->i = x
pop %rbx
pop %rbp
/* EXPORT DELETE END */
ret
SET_SIZE(arcfour_crypt)
#else
/* LINTED */
#endif /* !lint && !__lint */