5488N/A# gdb macros which may be useful for folks using gdb to debug

5488N/A# apache. Delete it if it bothers you.

5488N/A

5488N/Adefine dump_table

5488N/A set $t = (apr_table_entry_t *)((apr_array_header_t *)$arg0)->elts

5488N/A set $n = ((apr_array_header_t *)$arg0)->nelts

5488N/A set $i = 0

5488N/A while $i < $n

5488N/A if $t[$i].val == (void *)0L

5488N/A printf "[%u] '%s'=>NULL\n", $i, $t[$i].key

5488N/A else

5488N/A printf "[%u] '%s'='%s' [%p]\n", $i, $t[$i].key, $t[$i].val, $t[$i].val

5488N/A end

5488N/A set $i = $i + 1

5488N/A end

5488N/Aend

5488N/Adocument dump_table

5488N/A Print the key/value pairs in a table.

5488N/Aend

5488N/A

6083N/Adefine dump_skiplist

6083N/A set $sl = (apr_skiplist *)$arg0

5488N/A set $m = $sl->bottom

5488N/A printf "skiplist@%p: size=%lu: height=%d\n", $sl, $sl->size, $sl->height

6083N/A while ($m)

5488N/A printf "(%p,%.12lx)", $m, $m->data

5488N/A set $u = $m->up

5488N/A while ($u)

6083N/A printf " (%p,%.12lx)", $u, $u->data

6083N/A set $u = $u->up

6083N/A end

6083N/A printf "\n"

6083N/A set $m = $m->next

6083N/A end

6083N/Aend

6083N/Adocument dump_skiplist

6083N/A Print the nodes/values in a skiplist

6083N/Aend

5488N/A

5488N/Adefine dump_string_hash

5488N/A set $h = $arg0->array

6083N/A set $n = $arg0->max

5488N/A set $i = 0

5488N/A while $i < $n

5488N/A set $ent = $h[$i]

5488N/A while $ent != (void *)0L

6083N/A printf "'%s' => '%p'\n", $ent->key, $ent->val

5488N/A set $ent = $ent->next

5502N/A end

5502N/A set $i = $i + 1

5502N/A end

5502N/Aend

5502N/Adocument dump_string_hash

5502N/A Print the entries in a hash table indexed by strings

5502N/Aend

6142N/A

6142N/Adefine dump_string_shash

6142N/A set $h = $arg0->array

6142N/A set $n = $arg0->max

5488N/A set $i = 0

5488N/A while $i < $n

5488N/A set $ent = $h[$i]

5488N/A while $ent != (void *)0L

5488N/A printf "'%s' => '%s'\n", $ent->key, $ent->val

5488N/A set $ent = $ent->next

5488N/A end

5488N/A set $i = $i + 1

5488N/A end

5488N/Aend

5488N/Adocument dump_string_shash

5488N/A Print the entries in a hash table indexed by strings with string values

5488N/Aend

5680N/A

5488N/Adefine ro

5488N/A run -DONE_PROCESS

5488N/Aend

5488N/A

5488N/Adefine dump_string_array

5488N/A set $a = (char **)((apr_array_header_t *)$arg0)->elts

5488N/A set $n = (int)((apr_array_header_t *)$arg0)->nelts

5488N/A set $i = 0

5488N/A while $i < $n

5488N/A printf "[%u] '%s'\n", $i, $a[$i]

5488N/A set $i = $i + 1

5488N/A end

5488N/Aend

5488N/Adocument dump_string_array

5488N/A Print all of the elements in an array of strings.

5488N/Aend

5488N/A

5488N/Adefine printmemn

5488N/A set $i = 0

5488N/A while $i < $arg1

5488N/A if $arg0[$i] < 0x20 || $arg0[$i] > 0x7e

5488N/A printf "~"

5488N/A else

5488N/A printf "%c", $arg0[$i]

5488N/A end

5488N/A set $i = $i + 1

5488N/A end

5488N/Aend

5488N/A

5488N/Adefine print_bkt_datacol

5488N/A # arg0 == column name

5488N/A # arg1 == format

5488N/A # arg2 == value

5488N/A # arg3 == suppress header?

5488N/A set $suppressheader = $arg3

5488N/A

5488N/A if !$suppressheader

5488N/A printf " "

5861N/A printf $arg0

5488N/A printf "="

5488N/A else

5488N/A printf " | "

5488N/A end

5861N/A printf $arg1, $arg2

5488N/Aend

5488N/A

5488N/Adefine dump_bucket_ex

5488N/A # arg0 == bucket

5488N/A # arg1 == suppress header?

5488N/A set $bucket = (struct apr_bucket *)$arg0

5488N/A set $sh = $arg1

5488N/A set $refcount = -1

5488N/A

5488N/A print_bkt_datacol "bucket" "%-9s" $bucket->type->name $sh

5488N/A printf "(0x%08lx)", (unsigned long)$bucket

5488N/A print_bkt_datacol "length" "%-6ld" (long)($bucket->length) $sh

5488N/A print_bkt_datacol "data" "0x%08lx" $bucket->data $sh

5488N/A

5488N/A if !$sh

5488N/A printf "\n "

5680N/A end

5488N/A

5488N/A if (($bucket->type == &apr_bucket_type_eos) || \

5695N/A ($bucket->type == &apr_bucket_type_flush))

5488N/A

5488N/A # metadata buckets, no content

5488N/A print_bkt_datacol "contents" "%c" ' ' $sh

5488N/A printf " "

5488N/A print_bkt_datacol "rc" "n/%c" 'a' $sh

5695N/A

5488N/A else

5488N/A if ($bucket->type == &ap_bucket_type_error)

5488N/A

5488N/A # metadata bucket, no content but it does have an error code in it

5695N/A print_bkt_datacol "contents" "%c" ' ' $sh

5488N/A set $status = ((ap_bucket_error *)$bucket->data)->status

5488N/A printf " (status=%3d) ", $status

5488N/A print_bkt_datacol "rc" "n/%c" 'a' $sh

5488N/A

5488N/A else

5488N/A if (($bucket->type == &apr_bucket_type_file) || \

5488N/A ($bucket->type == &apr_bucket_type_pipe) || \

5488N/A ($bucket->type == &apr_bucket_type_socket))

5488N/A

5488N/A # buckets that contain data not in memory (ie not printable)

5488N/A

5488N/A print_bkt_datacol "contents" "[**unprintable**%c" ']' $sh

5488N/A printf " "

5488N/A if $bucket->type == &apr_bucket_type_file

5488N/A set $refcount = ((apr_bucket_refcount *)$bucket->data)->refcount

5488N/A print_bkt_datacol "rc" "%d" $refcount $sh

5488N/A end

5488N/A

5488N/A else

5488N/A if (($bucket->type == &apr_bucket_type_heap) || \

5488N/A ($bucket->type == &apr_bucket_type_pool) || \

5488N/A ($bucket->type == &apr_bucket_type_mmap) || \

5488N/A ($bucket->type == &apr_bucket_type_transient) || \

5488N/A ($bucket->type == &apr_bucket_type_immortal))

5488N/A

5488N/A # in-memory buckets

5488N/A

5488N/A if $bucket->type == &apr_bucket_type_heap

5488N/A set $refcount = ((apr_bucket_refcount *)$bucket->data)->refcount

5488N/A set $p = (apr_bucket_heap *)$bucket->data

5488N/A set $data = $p->base+$bucket->start

5488N/A

5488N/A else

5488N/A if $bucket->type == &apr_bucket_type_pool

5488N/A set $refcount = ((apr_bucket_refcount *)$bucket->data)->refcount

5488N/A set $p = (apr_bucket_pool *)$bucket->data

5488N/A if !$p->pool

5488N/A set $p = (apr_bucket_heap *)$bucket->data

5488N/A end

5488N/A set $data = $p->base+$bucket->start

5930N/A

5488N/A else

5488N/A if $bucket->type == &apr_bucket_type_mmap

6083N/A # is this safe if not APR_HAS_MMAP?

5488N/A set $refcount = ((apr_bucket_refcount *)$bucket->data)->refcount

5488N/A set $p = (apr_bucket_mmap *)$bucket->data

6021N/A set $data = ((char *)$p->mmap->mm)+$bucket->start

else

if (($bucket->type == &apr_bucket_type_transient) || \

($bucket->type == &apr_bucket_type_immortal))

set $data = ((char *)$bucket->data)+$bucket->start

end

end

end

end

if $sh

printf " | ["

else

printf " contents=["

end

set $datalen = $bucket->length

if $datalen > 17

printmem $data 17

printf "..."

set $datalen = 20

else

printmemn $data $datalen

end

printf "]"

while $datalen < 20

printf " "

set $datalen = $datalen + 1

end

if $refcount != -1

print_bkt_datacol "rc" "%d" $refcount $sh

else

print_bkt_datacol "rc" "n/%c" 'a' $sh

end

else

# 3rd-party bucket type

print_bkt_datacol "contents" "[**unknown**%c" ']' $sh

printf " "

print_bkt_datacol "rc" "n/%c" 'a' $sh

end

end

end

end

printf "\n"

end

define dump_bucket

dump_bucket_ex $arg0 0

end

document dump_bucket

Print bucket info

end

define dump_brigade

set $bb = (apr_bucket_brigade *)$arg0

set $bucket = $bb->list.next

set $sentinel = ((char *)((&($bb->list)) \

- ((size_t) &((struct apr_bucket *)0)->link)))

printf "dump of brigade 0x%lx\n", (unsigned long)$bb

printf " | type (address) | length | "

printf "data addr | contents | rc\n"

printf "----------------------------------------"

printf "----------------------------------------\n"

if $bucket == $sentinel

printf "brigade is empty\n"

end

set $j = 0

while $bucket != $sentinel

printf "%2d", $j

dump_bucket_ex $bucket 1

set $j = $j + 1

set $bucket = $bucket->link.next

end

printf "end of brigade\n"

end

document dump_brigade

Print bucket brigade info

end

define dump_filters

set $f = $arg0

while $f

printf "%s(0x%lx): ctx=0x%lx, r=0x%lx, c=0x%lx\n", \

$f->frec->name, (unsigned long)$f, (unsigned long)$f->ctx, \

$f->r, $f->c

set $f = $f->next

end

end

document dump_filters

Print filter chain info

end

define dump_filter_chain

set $r = $arg0

set $f = $r->output_filters

while $f

if $f == $r->output_filters

printf "r->output_filters =>\n"

end

if $f == $r->proto_output_filters

printf "r->proto_output_filters =>\n"

end

if $f == $r->connection->output_filters

printf "r->connection->output_filters =>\n"

end

printf " %s(0x%lx): type=%d, ctx=0x%lx, r=%s(0x%lx), c=0x%lx\n", \

$f->frec->name, (unsigned long)$f, $f->frec->ftype, (unsigned long)$f->ctx, \

$f->r == $r ? "r" : ($f->r == 0L ? "null" : \

($f->r == $r->main ? "r->main" : \

($r->main && $f->r == $r->main->main ? "r->main->main" : "????"))), \

$f->r, $f->c

set $f = $f->next

end

end

document dump_filter_chain

Print filter chain info given a request_rec pointer

end

define dump_process_rec

set $p = $arg0

printf "process_rec=0x%lx:\n", (unsigned long)$p

printf " pool=0x%lx, pconf=0x%lx\n", \

(unsigned long)$p->pool, (unsigned long)$p->pconf

end

document dump_process_rec

Print process_rec info

end

define dump_server_rec

set $s = $arg0

printf "name=%s:%d\n", \

$s->server_hostname, $s->port

dump_process_rec($s->process)

end

document dump_server_rec

Print server_rec info

end

define dump_servers

set $s = $arg0

while $s

dump_server_rec($s)

printf "\n"

set $s = $s->next

end

end

document dump_servers

Print server_rec list info

end

define dump_request_tree

set $r = $arg0

set $i

while $r

printf "r=(0x%lx): uri=%s, handler=%s, r->main=0x%lx\n", \

$r, $r->unparsed_uri, $r->handler ? $r->handler : "(none)", $r->main

set $r = $r->main

end

end

define dump_allocator

printf "Allocator current_free_index = %d, max_free_index = %d\n", \

($arg0)->current_free_index, ($arg0)->max_free_index

printf "Allocator free list:\n"

set $i = 0

set $max =(sizeof $arg0->free)/(sizeof $arg0->free[0])

set $kb = 0

while $i < $max

set $node = $arg0->free[$i]

if $node != 0

printf " #%2d: ", $i

while $node != 0

printf "%d, ", 4096 << $node->index

set $kb = $kb + (4 << $node->index)

set $node = $node->next

end

printf "ends.\n"

end

set $i = $i + 1

end

printf "Sum of free blocks: %dkiB\n", $kb

end

document dump_allocator

Print status of an allocator and its freelists.

end

define dump_one_pool

set $p = $arg0

set $size = 0

set $free = 0

set $nodes = 0

set $node = $arg0->active

set $done = 0

while $done == 0

set $size = $size + (4096 << $node->index)

set $free = $free + ($node->endp - $node->first_avail)

set $nodes = $nodes + 1

set $node = $node->next

if $node == $arg0->active

set $done = 1

end

end

printf "Pool '%s' [%p]: %d/%d free (%d blocks)\n", $p->tag, $p, $free, $size, $nodes

end

# Set sane defaults for common signals:

handle SIGPIPE noprint pass nostop

handle SIGUSR1 print pass nostop