resource/admin/metaMO.xsl

	metaMO.xsl revision 4129
0N/A<!--
0N/A  ! CDDL HEADER START
0N/A  !
0N/A  ! The contents of this file are subject to the terms of the
0N/A  ! Common Development and Distribution License, Version 1.0 only
0N/A  ! (the "License").  You may not use this file except in compliance
0N/A  ! with the License.
0N/A  !
0N/A  ! You can obtain a copy of the license at
0N/A  ! trunk/opends/resource/legal-notices/OpenDS.LICENSE
0N/A  ! or https://OpenDS.dev.java.net/OpenDS.LICENSE.
0N/A  ! See the License for the specific language governing permissions
0N/A  ! and limitations under the License.
0N/A  !
0N/A  ! When distributing Covered Code, include this CDDL HEADER in each
0N/A  ! file and include the License file at
0N/A  ! trunk/opends/resource/legal-notices/OpenDS.LICENSE.  If applicable,
0N/A  ! add the following below this CDDL HEADER, with the fields enclosed
0N/A  ! by brackets "[]" replaced with your own identifying information:
0N/A  !      Portions Copyright [yyyy] [name of copyright owner]
0N/A  !
0N/A  ! CDDL HEADER END
0N/A  !
0N/A  !
0N/A  !      Copyright 2007-2009 Sun Microsystems, Inc.
0N/A  ! -->
0N/A<xsl:stylesheet version="1.0" xmlns:adm="http://www.opends.org/admin"
0N/A  xmlns:admpp="http://www.opends.org/admin-preprocessor"
0N/A  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
0N/A  xmlns:exsl="http://exslt.org/common">
0N/A  <xsl:import href="java-utilities.xsl" />
0N/A  <xsl:import href="preprocessor.xsl" />
0N/A  <xsl:import href="property-types.xsl" />
0N/A  <xsl:output method="text" encoding="us-ascii" />
0N/A  <!--
0N/A    Template for generating the class declaration.
0N/A  -->
0N/A  <xsl:template name="generate-meta-class-declaration">
0N/A    <xsl:value-of select="'/**&#xa;'" />
0N/A    <xsl:call-template name="add-java-comment">
0N/A      <xsl:with-param name="indent-text" select="' *'" />
0N/A      <xsl:with-param name="content"
0N/A        select="concat('An interface for querying the ', $this-ufn,
0N/A                       ' managed object definition meta information.')" />
0N/A    </xsl:call-template>
0N/A    <xsl:value-of select="' * &lt;p&gt;&#xa;'" />
0N/A    <xsl:call-template name="add-java-comment">
0N/A      <xsl:with-param name="indent-text" select="' *'" />
0N/A      <xsl:with-param name="content" select="$this/adm:synopsis" />
0N/A    </xsl:call-template>
0N/A    <xsl:value-of select="' */&#xa;'" />
0N/A    <xsl:value-of
0N/A      select="concat('public final class ',
0N/A                     $this-java-class,
0N/A                     'CfgDefn extends ')" />
0N/A    <xsl:choose>
0N/A      <xsl:when test="$this-is-abstract">
0N/A        <xsl:value-of
0N/A          select="concat('AbstractManagedObjectDefinition&lt;',
0N/A                         $this-java-class, 'CfgClient, ',
0N/A                         $this-java-class, 'Cfg&gt; {&#xa;')" />
0N/A      </xsl:when>
0N/A      <xsl:otherwise>
0N/A        <xsl:value-of
0N/A          select="concat('ManagedObjectDefinition&lt;',
0N/A                         $this-java-class, 'CfgClient, ',
0N/A                         $this-java-class, 'Cfg&gt; {&#xa;')" />
0N/A      </xsl:otherwise>
0N/A    </xsl:choose>
0N/A  </xsl:template>
0N/A  <!--
0N/A    Template for generating the meta class body.
0N/A  -->
0N/A  <xsl:template name="generate-meta-class-body">
0N/A    <!--
0N/A      Singleton configuration definition instance.
0N/A    -->
0N/A    <xsl:value-of
0N/A      select="concat('  // The singleton configuration definition instance.&#xa;',
0N/A                     '  private static final ',
0N/A                     $this-java-class ,
0N/A                     'CfgDefn INSTANCE = new ', $this-java-class, 'CfgDefn();&#xa;')" />
0N/A    <!--
0N/A      Generate enumerations defined by this managed object..
0N/A    -->
0N/A    <xsl:for-each
0N/A      select="$this-local-properties[adm:syntax/adm:enumeration and not(adm:profile[@name='preprocessor']/adm:first-defined-in)]">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:if
0N/A        test="not(adm:profile[@name='preprocessor']/admpp:first-defined-in)">
0N/A        <xsl:text>&#xa;</xsl:text>
0N/A        <xsl:text>&#xa;</xsl:text>
0N/A        <xsl:text>&#xa;</xsl:text>
0N/A        <xsl:call-template name="generate-enumeration" />
0N/A      </xsl:if>
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Define application tags if this is the root configuration.
0N/A    -->
0N/A    <xsl:if test="$this-is-root">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:value-of select="'  // Define managed object tags.&#xa;'" />
0N/A      <xsl:value-of select="'  static {&#xa;'" />
0N/A      <xsl:for-each select="$this/adm:tag-definition">
0N/A        <xsl:sort select="@name" />
0N/A        <xsl:value-of
0N/A          select="concat('    Tag.define(&quot;', @name, '&quot;);&#xa;')" />
0N/A      </xsl:for-each>
0N/A      <xsl:value-of select="'  }&#xa;'" />
0N/A    </xsl:if>
0N/A    <!--
0N/A      Generate declarations for properties defined or
0N/A      overridden by this managed object.
0N/A    -->
0N/A    <xsl:for-each select="$this-local-properties">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-property-declaration" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Generate declarations for relations.
0N/A    -->
0N/A    <xsl:for-each select="$this-local-relations">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-relation-declaration" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Generate constructors for properties defined or
0N/A      overridden by this managed object.
0N/A    -->
0N/A    <xsl:for-each select="$this-local-properties">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-property-constructor" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Generate constructors for relations.
0N/A    -->
0N/A    <xsl:for-each select="$this-local-relations">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-relation-constructor" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Register any optins associated with this managed object definition.
0N/A    -->
0N/A    <xsl:if test="$this-is-advanced or $this-is-hidden">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:value-of
0N/A        select="'  // Register the options associated with this managed object definition.&#xa;'" />
0N/A      <xsl:value-of select="'  static {&#xa;'" />
0N/A      <xsl:if test="$this-is-advanced">
0N/A        <xsl:value-of
0N/A          select="concat('    INSTANCE.registerOption(ManagedObjectOption.ADVANCED);&#xa;')" />
0N/A      </xsl:if>
0N/A      <xsl:if test="$this-is-hidden">
0N/A        <xsl:value-of
0N/A          select="concat('    INSTANCE.registerOption(ManagedObjectOption.HIDDEN);&#xa;')" />
0N/A      </xsl:if>
0N/A      <xsl:value-of select="'  }&#xa;'" />
0N/A    </xsl:if>
0N/A    <!--
0N/A      Register any tags associated with this managed object definition.
0N/A    -->
0N/A    <xsl:if test="$this/adm:tag">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:value-of
0N/A        select="'  // Register the tags associated with this managed object definition.&#xa;'" />
0N/A      <xsl:value-of select="'  static {&#xa;'" />
0N/A      <xsl:for-each select="$this/adm:tag">
0N/A        <xsl:sort select="@name" />
0N/A        <xsl:value-of
0N/A          select="concat('    INSTANCE.registerTag(Tag.valueOf(&quot;', @name, '&quot;));&#xa;')" />
0N/A      </xsl:for-each>
0N/A      <xsl:value-of select="'  }&#xa;'" />
0N/A    </xsl:if>
0N/A    <!--
0N/A      Register any constraints associated with this managed object definition.
0N/A    -->
0N/A    <xsl:if test="$this/adm:constraint">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:value-of
0N/A        select="'  // Register the constraints associated with this managed object definition.&#xa;'" />
0N/A      <xsl:value-of select="'  static {&#xa;'" />
0N/A      <xsl:for-each select="$this/adm:constraint">
0N/A        <xsl:value-of
0N/A          select="concat('    INSTANCE.registerConstraint(new GenericConstraint(INSTANCE, ', position(), ', ')" />
0N/A        <xsl:apply-templates select="adm:condition/*"
0N/A          mode="compile-condition" />
0N/A        <xsl:value-of select="'));&#xa;'" />
0N/A      </xsl:for-each>
0N/A      <xsl:value-of select="'  }&#xa;'" />
0N/A    </xsl:if>
0N/A    <!--
0N/A      Configuration definition singleton getter.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of select="'  /**&#xa;'" />
0N/A    <xsl:call-template name="add-java-comment">
0N/A      <xsl:with-param name="indent-text" select="'   *'" />
0N/A      <xsl:with-param name="content"
0N/A        select="concat('Get the ', $this-ufn,' configuration definition singleton.')" />
0N/A    </xsl:call-template>
0N/A    <xsl:value-of select="'   *&#xa;'" />
0N/A    <xsl:call-template name="add-java-comment">
0N/A      <xsl:with-param name="indent-text" select="'   *'" />
0N/A      <xsl:with-param name="indent-text2" select="'   *        '" />
0N/A      <xsl:with-param name="content"
0N/A        select="concat('@return Returns the ', $this-ufn,
0N/A                     ' configuration definition singleton.')" />
0N/A    </xsl:call-template>
0N/A    <xsl:value-of select="'   */&#xa;'" />
0N/A    <xsl:value-of
0N/A      select="concat('  public static ',
0N/A                     $this-java-class ,
0N/A                     'CfgDefn getInstance() {&#xa;',
0N/A                     '    return INSTANCE;&#xa;',
0N/A                     '  }&#xa;')" />
0N/A    <!--
0N/A      Private constructor.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of
0N/A      select="concat('  /**&#xa;',
0N/A                     '   * Private constructor.&#xa;',
0N/A                     '   */&#xa;',
0N/A                     '  private ',
0N/A                     $this-java-class ,
0N/A                     'CfgDefn() {&#xa;')" />
0N/A    <xsl:choose>
0N/A      <xsl:when test="boolean($this/@extends)">
0N/A        <xsl:value-of
0N/A          select="concat('    super(&quot;',
0N/A                         $this/@name,
0N/A                         '&quot;, ',
0N/A                         $parent-java-class,
0N/A                         'CfgDefn.getInstance());&#xa;')" />
0N/A      </xsl:when>
0N/A      <xsl:otherwise>
0N/A        <xsl:value-of
0N/A          select="concat('    super(&quot;',
0N/A                         $this/@name,
0N/A                         '&quot;, TopCfgDefn.getInstance());&#xa;')" />
0N/A      </xsl:otherwise>
0N/A    </xsl:choose>
0N/A    <xsl:value-of select="'  }&#xa;'" />
0N/A    <!--
0N/A      Create configuration view factory methods for non-abstract definitions
0N/A    -->
0N/A    <xsl:if test="not($this-is-abstract)">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <!--
0N/A        Generate configuration client factory method.
0N/A      -->
0N/A      <xsl:value-of
0N/A        select="concat('  /**&#xa;',
0N/A                       '   * {@inheritDoc}&#xa;',
0N/A                       '   */&#xa;',
0N/A                       '  public ',
0N/A                       $this-java-class,
0N/A                       'CfgClient createClientConfiguration(&#xa;',
0N/A                       '      ManagedObject&lt;? extends ',
0N/A                       $this-java-class,
0N/A                       'CfgClient&gt; impl) {&#xa;',
0N/A                       '    return new ',
0N/A                       $this-java-class ,
0N/A                       'CfgClientImpl(impl);&#xa;',
0N/A                       '  }&#xa;')" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <!--
0N/A        Generate configuration server factory method.
0N/A      -->
0N/A      <xsl:value-of
0N/A        select="concat('  /**&#xa;',
0N/A                       '   * {@inheritDoc}&#xa;',
0N/A                       '   */&#xa;',
0N/A                       '  public ',
0N/A                       $this-java-class,
0N/A                       'Cfg createServerConfiguration(&#xa;',
0N/A                       '      ServerManagedObject&lt;? extends ',$this-java-class,'Cfg&gt; impl) {&#xa;',
0N/A                       '    return new ',
0N/A                       $this-java-class ,
0N/A                       'CfgServerImpl(impl);&#xa;',
0N/A                       '  }&#xa;')" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <!--
0N/A        Generate configuration server class getter..
0N/A      -->
0N/A      <xsl:value-of
0N/A        select="concat('  /**&#xa;',
0N/A                       '   * {@inheritDoc}&#xa;',
0N/A                       '   */&#xa;',
0N/A                       '  public Class&lt;',
0N/A                       $this-java-class,
0N/A                       'Cfg&gt; getServerConfigurationClass() {&#xa;',
0N/A                       '    return ',
0N/A                       $this-java-class ,
0N/A                       'Cfg.class;&#xa;',
0N/A                       '  }&#xa;')" />
0N/A    </xsl:if>
0N/A    <!--
0N/A      Generate property definition getters for all properties.
0N/A    -->
0N/A    <xsl:for-each select="$this-all-properties">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-property-definition-getter" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Generate relation definition getters for all relations.
0N/A    -->
0N/A    <xsl:for-each select="$this-all-relations">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-relation-definition-getter" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Managed object class implementations.
0N/A    -->
0N/A    <xsl:if test="not($this-is-abstract)">
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-client-impl-class" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-server-impl-class" />
0N/A    </xsl:if>
0N/A  </xsl:template>
0N/A  <!--
0N/A    Generate managed object client class implementation.
0N/A  -->
0N/A  <xsl:template name="generate-client-impl-class">
0N/A    <!--
0N/A      Declaration.
0N/A    -->
0N/A    <xsl:value-of
0N/A      select="concat('  /**&#xa;',
0N/A                     '   * Managed object client implementation.&#xa;',
0N/A                     '   */&#xa;',
0N/A                     '  private static class ',
0N/A                     $this-java-class ,
0N/A                     'CfgClientImpl implements&#xa;    ',
0N/A                     $this-java-class ,
0N/A                     'CfgClient {&#xa;')" />
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <!--
0N/A      Private instance.
0N/A    -->
0N/A    <xsl:value-of
0N/A      select="concat('    // Private implementation.&#xa;',
0N/A                     '    private ManagedObject&lt;? extends ',
0N/A                     $this-java-class,
0N/A                     'CfgClient&gt; impl;&#xa;')" />
0N/A    <!--
0N/A      Private constructor.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of
0N/A      select="concat('    // Private constructor.&#xa;',
0N/A                     '    private ',
0N/A                     $this-java-class,
0N/A                     'CfgClientImpl(&#xa;',
0N/A                     '        ManagedObject&lt;? extends ',
0N/A                     $this-java-class,
0N/A                     'CfgClient&gt; impl) {&#xa;',
0N/A                     '      this.impl = impl;&#xa;',
0N/A                     '    }&#xa;')" />
0N/A    <!--
0N/A      Getters/Setters for all properties.
0N/A    -->
0N/A    <xsl:for-each select="$this-all-properties">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template
0N/A        name="generate-property-getter-implementation">
0N/A        <xsl:with-param name="interface" select="'client'" />
0N/A      </xsl:call-template>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-property-setter-implementation" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Relation methods.
0N/A    -->
0N/A    <xsl:for-each select="$this-all-relations">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:call-template name="generate-client-relation-methods" />
0N/A    </xsl:for-each>
0N/A    <!--
0N/A      Managed object definition getter.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of
0N/A      select="concat('    /**&#xa;',
0N/A                     '     * {@inheritDoc}&#xa;',
0N/A                     '     */&#xa;',
0N/A                     '    public ManagedObjectDefinition&lt;? extends ', $this-java-class,'CfgClient, ? extends ', $this-java-class,'Cfg&gt; definition() {&#xa;',
0N/A                     '      return INSTANCE;&#xa;',
0N/A                     '    }&#xa;')" />
0N/A    <!--
0N/A      Property provider view.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of
0N/A      select="concat('    /**&#xa;',
0N/A                     '     * {@inheritDoc}&#xa;',
0N/A                     '     */&#xa;',
0N/A                     '    public PropertyProvider properties() {&#xa;',
0N/A                     '      return impl;&#xa;',
0N/A                     '    }&#xa;')" />
0N/A    <!--
0N/A      Commit method.
0N/A    -->
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of
0N/A      select="concat('    /**&#xa;',
0N/A                     '     * {@inheritDoc}&#xa;',
0N/A                     '     */&#xa;',
0N/A                     '    public void commit() throws ManagedObjectAlreadyExistsException,&#xa;',
0N/A                     '        MissingMandatoryPropertiesException, ConcurrentModificationException,&#xa;',
0N/A                     '        OperationRejectedException, AuthorizationException,&#xa;',
0N/A                     '        CommunicationException {&#xa;',
0N/A                     '      impl.commit();&#xa;',
0N/A                     '    }&#xa;')" />
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <xsl:value-of select="'  }&#xa;'" />
0N/A  </xsl:template>
0N/A  <!--
0N/A    Generate managed object server class implementation.
0N/A  -->
0N/A  <xsl:template name="generate-server-impl-class">
0N/A    <!--
0N/A      Declaration.
0N/A    -->
0N/A    <xsl:value-of
0N/A      select="concat('  /**&#xa;',
0N/A                     '   * Managed object server implementation.&#xa;',
0N/A                     '   */&#xa;',
0N/A                     '  private static class ',
0N/A                     $this-java-class ,
0N/A                     'CfgServerImpl implements&#xa;    ',
0N/A                     $this-java-class ,
0N/A                     'Cfg {&#xa;')" />
0N/A    <xsl:text>&#xa;</xsl:text>
0N/A    <!--
0N/A      Private instance.
0N/A    -->
0N/A    <xsl:value-of
0N/A      select="concat('    // Private implementation.&#xa;',
0N/A                     '    private ServerManagedObject&lt;? extends ', $this-java-class, 'Cfg&gt; impl;&#xa;')" />
0N/A    <!--
0N/A      Private members for each property.
0N/A    -->
0N/A    <xsl:for-each select="$this-all-properties">
0N/A      <xsl:sort select="@name" />
0N/A      <xsl:text>&#xa;</xsl:text>
0N/A      <xsl:value-of
0N/A        select="concat('    // The value of the &quot;', @name, '&quot; property.&#xa;')" />
0N/A      <xsl:value-of select="'    private final '" />
0N/A      <xsl:choose>
0N/A        <xsl:when test="string(@multi-valued) != 'true'">
0N/A          <xsl:choose>
0N/A            <xsl:when test="adm:default-behavior/adm:defined">
0N/A              <!--
0N/A                The property is guaranteed to contain a value since there is a
0N/A                well-defined default value.
0N/A              -->
0N/A              <xsl:call-template
0N/A                name="get-property-java-primitive-type" />
0N/A            </xsl:when>
0N/A            <xsl:when test="@mandatory = 'true'">
0N/A              <!--
0N/A                The property is guaranteed to contain a value in the server interface.
0N/A              -->
0N/A              <xsl:call-template
0N/A                name="get-property-java-primitive-type" />
0N/A            </xsl:when>
0N/A            <xsl:otherwise>
0N/A              <xsl:call-template name="get-property-java-type" />
0N/A            </xsl:otherwise>
0N/A          </xsl:choose>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="'SortedSet&lt;'" />
          <xsl:call-template name="get-property-java-type" />
          <xsl:value-of select="'&gt;'" />
        </xsl:otherwise>
      </xsl:choose>
      <xsl:value-of select="' p'" />
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
      <xsl:value-of select="';&#xa;'" />
    </xsl:for-each>
    <!--
      Private constructor.
    -->
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of
      select="concat('    // Private constructor.&#xa;',
                     '    private ',
                     $this-java-class,
                     'CfgServerImpl(ServerManagedObject&lt;? extends ', $this-java-class, 'Cfg&gt; impl) {&#xa;',
                     '      this.impl = impl;&#xa;')" />
    <xsl:for-each select="$this-all-properties">
      <xsl:sort select="@name" />
      <xsl:variable name="java-prop-name">
        <xsl:call-template name="name-to-java">
          <xsl:with-param name="value" select="@name" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of
        select="concat('      this.p', $java-prop-name, ' = ')" />
      <xsl:choose>
        <xsl:when test="string(@multi-valued) != 'true'">
          <xsl:value-of
            select="concat('impl.getPropertyValue(INSTANCE.get', $java-prop-name , 'PropertyDefinition());&#xa;')" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of
            select="concat('impl.getPropertyValues(INSTANCE.get', $java-prop-name , 'PropertyDefinition());&#xa;')" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
    <xsl:value-of select="'    }&#xa;'" />
    <!--
      Generate all the change listener methods - one for each managed
      object in the hierarchy.
    -->
    <xsl:if test="not($this-is-root)">
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:call-template name="generate-change-listener" />
    </xsl:if>
    <!--
      Getters for all properties.
    -->
    <xsl:for-each select="$this-all-properties">
      <xsl:sort select="@name" />
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:call-template
        name="generate-property-getter-implementation">
        <xsl:with-param name="interface" select="'server'" />
      </xsl:call-template>
    </xsl:for-each>
    <!--
      Relation methods.
    -->
    <xsl:for-each select="$this-all-relations">
      <xsl:sort select="@name" />
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:text>&#xa;</xsl:text>
      <xsl:call-template name="generate-server-relation-methods" />
    </xsl:for-each>
    <!--
      Configuration class getter.
    -->
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of
      select="concat('    /**&#xa;',
                     '     * {@inheritDoc}&#xa;',
                     '     */&#xa;',
                     '    public Class&lt;? extends ', $this-java-class,'Cfg&gt; configurationClass() {&#xa;',
                     '      return ', $this-java-class, 'Cfg.class;&#xa;',
                     '    }&#xa;')" />
    <!--
      Configuration entry DN getter.
    -->
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of
      select="concat('    /**&#xa;',
                     '     * {@inheritDoc}&#xa;',
                     '     */&#xa;',
                     '    public DN dn() {&#xa;',
                     '      return impl.getDN();&#xa;',
                     '    }&#xa;')" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of select="'  }&#xa;'" />
  </xsl:template>
  <!--
    Generate a property definition constructor.
  -->
  <xsl:template name="generate-property-declaration">
    <xsl:variable name="java-prop-name">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="type">
      <xsl:call-template name="get-property-definition-type" />
    </xsl:variable>
    <xsl:variable name="generic-type">
      <xsl:call-template name="get-property-definition-generic-type" />
    </xsl:variable>
    <xsl:variable name="pdtype">
      <xsl:choose>
        <xsl:when test="string-length($generic-type) != 0">
          <xsl:value-of
            select="concat($type, '&lt;', $generic-type, '&gt;')" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$type" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:value-of
      select="concat('  // The &quot;',
                     @name,
                     '&quot; property definition.&#xa;',
                     '  private static final ', $pdtype, ' PD_', $java-prop-name, ';&#xa;')" />
  </xsl:template>
  <!--
    Generate a property definition constructor.
  -->
  <xsl:template name="generate-property-constructor">
    <xsl:variable name="java-prop-name">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="type">
      <xsl:call-template name="get-property-definition-type" />
    </xsl:variable>
    <xsl:variable name="generic-type">
      <xsl:call-template name="get-property-definition-generic-type" />
    </xsl:variable>
    <xsl:variable name="value-type">
      <xsl:call-template name="get-property-java-type" />
    </xsl:variable>
    <xsl:value-of
      select="concat('  // Build the &quot;', @name, '&quot; property definition.&#xa;',
                                 '  static {&#xa;')" />
    <xsl:choose>
      <xsl:when test="string-length($generic-type) != 0">
        <xsl:value-of
          select="concat('      ', $type, '.Builder&lt;', $generic-type, '&gt; builder = ', $type, '.createBuilder(INSTANCE, &quot;',@name, '&quot;);&#xa;')" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of
          select="concat('      ', $type, '.Builder builder = ', $type, '.createBuilder(INSTANCE, &quot;',@name, '&quot;);&#xa;')" />
      </xsl:otherwise>
    </xsl:choose>
    <xsl:if test="@multi-valued='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.MULTI_VALUED);&#xa;'" />
    </xsl:if>
    <xsl:if test="@read-only='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.READ_ONLY);&#xa;'" />
    </xsl:if>
    <xsl:if test="@monitoring='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.MONITORING);&#xa;'" />
    </xsl:if>
    <xsl:if test="@mandatory='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.MANDATORY);&#xa;'" />
    </xsl:if>
    <xsl:if test="@hidden='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.HIDDEN);&#xa;'" />
    </xsl:if>
    <xsl:if test="@advanced='true'">
      <xsl:value-of
        select="'      builder.setOption(PropertyOption.ADVANCED);&#xa;'" />
    </xsl:if>
    <xsl:variable name="action-type">
      <xsl:choose>
        <xsl:when test="adm:requires-admin-action">
          <xsl:call-template name="name-to-java-constant">
            <xsl:with-param name="value"
              select="local-name(adm:requires-admin-action/*)" />
          </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="'NONE'" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:value-of
      select="concat('      builder.setAdministratorAction(new AdministratorAction(AdministratorAction.Type.', $action-type, ', INSTANCE, &quot;', @name, '&quot;));&#xa;')" />
    <xsl:choose>
      <xsl:when
        test="not(adm:default-behavior) or adm:default-behavior/adm:undefined">
        <xsl:value-of
          select="concat('      builder.setDefaultBehaviorProvider(new UndefinedDefaultBehaviorProvider&lt;', $value-type,'&gt;());&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:default-behavior/adm:alias">
        <xsl:value-of
          select="concat('      builder.setDefaultBehaviorProvider(new AliasDefaultBehaviorProvider&lt;', $value-type,'&gt;(INSTANCE, &quot;', @name, '&quot;));&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:default-behavior/adm:defined">
        <xsl:value-of
          select="concat('      DefaultBehaviorProvider&lt;', $value-type,'&gt; provider = ',
                             'new DefinedDefaultBehaviorProvider&lt;', $value-type,'&gt;(')" />
        <xsl:for-each
          select="adm:default-behavior/adm:defined/adm:value">
          <xsl:value-of
            select="concat('&quot;', normalize-space(), '&quot;')" />
          <xsl:if test="position() != last()">
            <xsl:value-of select="', '" />
          </xsl:if>
        </xsl:for-each>
        <xsl:value-of select="');&#xa;'" />
        <xsl:value-of
          select="'      builder.setDefaultBehaviorProvider(provider);&#xa;'" />
      </xsl:when>
      <xsl:when
        test="adm:default-behavior/adm:inherited/adm:relative">
        <xsl:value-of
          select="concat('      DefaultBehaviorProvider&lt;', $value-type,'&gt; provider = ',
                             'new RelativeInheritedDefaultBehaviorProvider&lt;', $value-type,'&gt;(')" />
        <xsl:variable name="managed-object-name">
          <xsl:call-template name="name-to-java">
            <xsl:with-param name="value"
              select="adm:default-behavior/adm:inherited/adm:relative/@managed-object-name" />
          </xsl:call-template>
        </xsl:variable>
        <xsl:variable name="property-name"
          select="adm:default-behavior/adm:inherited/adm:relative/@property-name" />
        <xsl:variable name="offset"
          select="adm:default-behavior/adm:inherited/adm:relative/@offset" />
        <xsl:value-of
          select="concat($managed-object-name, 'CfgDefn.getInstance(), &quot;', $property-name, '&quot;, ', $offset, ');&#xa;')" />
        <xsl:value-of
          select="'      builder.setDefaultBehaviorProvider(provider);&#xa;'" />
      </xsl:when>
      <xsl:when
        test="adm:default-behavior/adm:inherited/adm:absolute">
        <xsl:value-of
          select="concat('      DefaultBehaviorProvider&lt;', $value-type,'&gt; provider = ',
                             'new AbsoluteInheritedDefaultBehaviorProvider&lt;', $value-type,'&gt;(')" />
        <xsl:variable name="property-name"
          select="adm:default-behavior/adm:inherited/adm:absolute/@property-name" />
        <xsl:variable name="path"
          select="adm:default-behavior/adm:inherited/adm:absolute/@path" />
        <xsl:value-of
          select="concat('&quot;', $path, '&quot;, &quot;', $property-name, '&quot;);&#xa;')" />
        <xsl:value-of
          select="'      builder.setDefaultBehaviorProvider(provider);&#xa;'" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Unrecognized default behavior type for property &quot;', @name,
                         '&quot;.')" />
        </xsl:message>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:call-template name="get-property-definition-ctor" />
    <xsl:value-of
      select="concat('      PD_', $java-prop-name, ' = builder.getInstance();&#xa;')" />
    <xsl:value-of
      select="concat('      INSTANCE.registerPropertyDefinition(PD_', $java-prop-name, ');&#xa;')" />
    <xsl:call-template name="get-property-definition-post-ctor" />
    <xsl:value-of select="'  }&#xa;'" />
  </xsl:template>
  <!--
    Generate a relation definition declaration.
  -->
  <xsl:template name="generate-relation-declaration">
    <xsl:variable name="relation-name">
      <xsl:choose>
        <xsl:when test="adm:one-to-many">
          <xsl:value-of select="adm:one-to-many/@plural-name" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="@name" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:variable name="java-relation-name">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="$relation-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-managed-object-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@managed-object-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:value-of
      select="concat('  // The &quot;',
                     $relation-name,
                     '&quot; relation definition.&#xa;',
                     '  private static final ')" />
    <xsl:choose>
      <xsl:when test="adm:one-to-one">
        <xsl:text>SingletonRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="adm:one-to-zero-or-one">
        <xsl:text>OptionalRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="string(adm:one-to-many/@unique) != 'true'">
        <xsl:text>InstantiableRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="string(adm:one-to-many/@unique) = 'true'">
        <xsl:text>SetRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Unknown relation type &quot;', local-name(*), '&quot; in relation &quot;', @name, '&quot;.')" />
        </xsl:message>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:value-of
      select="concat($java-managed-object-name, 'CfgClient, ', $java-managed-object-name, 'Cfg&gt; RD_', $java-relation-name, ';&#xa;')" />
  </xsl:template>
  <!--
    Generate a relation definition constructor.
  -->
  <xsl:template name="generate-relation-constructor">
    <xsl:variable name="relation-name">
      <xsl:choose>
        <xsl:when test="adm:one-to-many">
          <xsl:value-of select="adm:one-to-many/@plural-name" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="@name" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:variable name="java-relation-name">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="$relation-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-managed-object-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@managed-object-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-relation-builder-type">
      <xsl:choose>
        <xsl:when test="adm:one-to-one">
          <xsl:text>SingletonRelationDefinition</xsl:text>
        </xsl:when>
        <xsl:when test="adm:one-to-zero-or-one">
          <xsl:text>OptionalRelationDefinition</xsl:text>
        </xsl:when>
        <xsl:when test="string(adm:one-to-many/@unique) != 'true'">
          <xsl:text>InstantiableRelationDefinition</xsl:text>
        </xsl:when>
        <xsl:when test="string(adm:one-to-many/@unique) = 'true'">
          <xsl:text>SetRelationDefinition</xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:message terminate="yes">
            <xsl:value-of
              select="concat('Unknown relation type &quot;', local-name(*), '&quot; in relation &quot;', @name, '&quot;.')" />
          </xsl:message>
        </xsl:otherwise>
      </xsl:choose>
      <xsl:value-of
        select="concat('.Builder&lt;', $java-managed-object-name, 'CfgClient, ', $java-managed-object-name, 'Cfg&gt;')" />
    </xsl:variable>
    <xsl:value-of
      select="concat('  // Build the &quot;', $relation-name, '&quot; relation definition.&#xa;',
                     '  static {&#xa;',
                     '    ', $java-relation-builder-type, ' builder =&#xa;',
                     '      new ', $java-relation-builder-type, '(INSTANCE, &quot;', @name, '&quot;, ')" />
    <xsl:if test="adm:one-to-many">
      <xsl:value-of
        select="concat('&quot;', adm:one-to-many/@plural-name, '&quot;, ')" />
    </xsl:if>
    <xsl:value-of
      select="concat($java-managed-object-name, 'CfgDefn.getInstance());&#xa;')" />
    <xsl:if test="adm:one-to-many/@naming-property">
      <xsl:if test="string(adm:one-to-many/@unique) = 'true'">
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Naming properties found in unique one-to-many relation &quot;', @name, '&quot;.')" />
        </xsl:message>
      </xsl:if>
      <xsl:variable name="java-property-name">
        <xsl:call-template name="name-to-java">
          <xsl:with-param name="value"
            select="adm:one-to-many/@naming-property" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of
        select="concat('    builder.setNamingProperty(',
                           $java-managed-object-name,
                           'CfgDefn.getInstance().get',
                           $java-property-name, 'PropertyDefinition());&#xa;')" />
    </xsl:if>
    <xsl:for-each select="*/adm:default-managed-object">
      <xsl:variable name="dmo-java-name">
        <xsl:call-template name="name-to-java">
          <xsl:with-param name="value" select="@managed-object-name" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:value-of select="'    {&#xa;'" />
      <xsl:value-of
        select="concat('      DefaultManagedObject.Builder&lt;',
                                   $dmo-java-name, 'CfgClient, ',
                                   $dmo-java-name, 'Cfg&gt; dmoBuilder = new DefaultManagedObject.Builder&lt;',
                                   $dmo-java-name, 'CfgClient, ',
                                   $dmo-java-name, 'Cfg&gt;(',
                                   $dmo-java-name, 'CfgDefn.getInstance());&#xa;')" />
      <xsl:for-each select="adm:property">
        <xsl:value-of
          select="concat('      dmoBuilder.setPropertyValues(&quot;', @name, '&quot;')" />
        <xsl:for-each select="adm:value">
          <xsl:value-of
            select="concat(', &quot;', normalize-space(), '&quot;')" />
        </xsl:for-each>
        <xsl:value-of select="');&#xa;'" />
      </xsl:for-each>
      <xsl:choose>
        <xsl:when test="@name">
          <xsl:value-of
            select="concat('      builder.setDefaultManagedObject(&quot;', @name, '&quot;, dmoBuilder.getInstance());&#xa;')" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of
            select="'      builder.setDefaultManagedObject(dmoBuilder.getInstance());&#xa;'" />
        </xsl:otherwise>
      </xsl:choose>
      <xsl:value-of select="'    }&#xa;'" />
    </xsl:for-each>
    <xsl:if test="@advanced='true'">
      <xsl:value-of
        select="'    builder.setOption(RelationOption.ADVANCED);&#xa;'" />
    </xsl:if>
    <xsl:if test="@hidden='true'">
      <xsl:value-of
        select="'    builder.setOption(RelationOption.HIDDEN);&#xa;'" />
    </xsl:if>
    <xsl:value-of
      select="concat('    RD_', $java-relation-name, ' = builder.getInstance();&#xa;')" />
    <xsl:value-of
      select="concat('    INSTANCE.registerRelationDefinition(RD_', $java-relation-name,');&#xa;')" />
    <xsl:value-of select="'  }&#xa;'" />
  </xsl:template>
  <!--
    Generate a property definition getter for a locally defined
    or overriden property.
  -->
  <xsl:template name="generate-property-definition-getter">
    <xsl:variable name="java-prop-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-prop-name-constant">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="type">
      <xsl:call-template name="get-property-definition-type" />
    </xsl:variable>
    <xsl:variable name="generic-type">
      <xsl:call-template name="get-property-definition-generic-type" />
    </xsl:variable>
    <xsl:variable name="pdtype">
      <xsl:choose>
        <xsl:when test="string-length($generic-type) != 0">
          <xsl:value-of
            select="concat($type, '&lt;', $generic-type, '&gt;')" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="$type" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:value-of
      select="concat('  /**&#xa;',
                     '   * Get the &quot;',
                     @name,
                     '&quot; property definition.&#xa;')" />
    <xsl:if test="adm:synopsis">
      <xsl:value-of select="'   * &lt;p&gt;&#xa;'" />
      <xsl:call-template name="add-java-comment">
        <xsl:with-param name="indent-text" select="'   *'" />
        <xsl:with-param name="content" select="adm:synopsis" />
      </xsl:call-template>
    </xsl:if>
    <xsl:if test="adm:description">
      <xsl:value-of select="'   * &lt;p&gt;&#xa;'" />
      <xsl:call-template name="add-java-comment">
        <xsl:with-param name="indent-text" select="'   *'" />
        <xsl:with-param name="content" select="adm:description" />
      </xsl:call-template>
    </xsl:if>
    <xsl:choose>
      <xsl:when
        test="adm:profile[@name='preprocessor']/admpp:last-defined-in[@name=$this-name and @package=$this-package]">
        <xsl:value-of
          select="concat('   *&#xa;',
                     '   * @return Returns the &quot;',
                     @name,
                     '&quot; property definition.&#xa;',
                     '   */&#xa;',
                     '  public ',
                     $pdtype,
                     ' get',
                     $java-prop-name,
                     'PropertyDefinition() {&#xa;' ,
                     '    return PD_',
                     $java-prop-name-constant ,
                     ';&#xa;' ,
                     '  }&#xa;')" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of
          select="concat('   *&#xa;',
                     '   * @return Returns the &quot;',
                     @name,
                     '&quot; property definition.&#xa;',
                     '   */&#xa;',
                     '  public ',
                     $pdtype,
                     ' get',
                     $java-prop-name,
                     'PropertyDefinition() {&#xa;' ,
                     '    return ',
                     $parent-java-class, 'CfgDefn.getInstance().get',
                     $java-prop-name,
                     'PropertyDefinition();&#xa;',
                     '  }&#xa;')" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <!--
    Generate a relation definition getter.
  -->
  <xsl:template name="generate-relation-definition-getter">
    <xsl:variable name="relation-name">
      <xsl:choose>
        <xsl:when test="adm:one-to-many">
          <xsl:value-of select="adm:one-to-many/@plural-name" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="@name" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:variable name="java-relation-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="$relation-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-relation-name-constant">
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="$relation-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:value-of
      select="concat('  /**&#xa;',
                     '   * Get the &quot;',
                     $relation-name,
                     '&quot; relation definition.&#xa;',
                     '   *&#xa;',
                     '   * @return Returns the &quot;',
                     $relation-name,
                     '&quot; relation definition.&#xa;',
                     '   */&#xa;',
                     '  public ')" />
    <xsl:choose>
      <xsl:when test="adm:one-to-one">
        <xsl:text>SingletonRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="adm:one-to-zero-or-one">
        <xsl:text>OptionalRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="string(adm:one-to-many/@unique) != 'true'">
        <xsl:text>InstantiableRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:when test="string(adm:one-to-many/@unique) = 'true'">
        <xsl:text>SetRelationDefinition&lt;</xsl:text>
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Unknown relation type &quot;', local-name(*), '&quot; in relation &quot;', @name, '&quot;.')" />
        </xsl:message>
      </xsl:otherwise>
    </xsl:choose>
    <xsl:variable name="java-managed-object-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@managed-object-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:choose>
      <xsl:when
        test="adm:profile[@name='preprocessor']/admpp:last-defined-in[@name=$this-name and @package=$this-package]">
        <xsl:value-of
          select="concat($java-managed-object-name, 'CfgClient,',
                     $java-managed-object-name, 'Cfg&gt; get',
                     $java-relation-name,
                     'RelationDefinition() {&#xa;' ,
                     '    return RD_',
                     $java-relation-name-constant,
                     ';&#xa;' ,
                     '  }&#xa;')" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:value-of
          select="concat($java-managed-object-name, 'CfgClient,',
                     $java-managed-object-name, 'Cfg&gt; get',
                     $java-relation-name,
                     'RelationDefinition() {&#xa;' ,
                     '    return ',
                     $parent-java-class, 'CfgDefn.getInstance().get',
                     $java-relation-name,
                     'RelationDefinition();&#xa;',
                     '  }&#xa;')" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <!--
    Generate client relation methods.
  -->
  <xsl:template name="generate-client-relation-methods">
    <xsl:variable name="name" select="@name" />
    <xsl:variable name="java-relation-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="$name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-class-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@managed-object-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:choose>
      <xsl:when test="adm:one-to-one">
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'CfgClient get', $java-relation-name, '()&#xa;',
                         '        throws DefinitionDecodingException, ManagedObjectDecodingException,&#xa;',
                         '        ManagedObjectNotFoundException, ConcurrentModificationException,&#xa;',
                         '        AuthorizationException, CommunicationException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-name,'RelationDefinition()).getConfiguration();&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:one-to-zero-or-one">
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public boolean has', $java-relation-name, '() throws ConcurrentModificationException,&#xa;',
                         '        AuthorizationException, CommunicationException {&#xa;',
                         '      return impl.hasChild(INSTANCE.get', $java-relation-name,'RelationDefinition());&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'CfgClient get', $java-relation-name, '()&#xa;',
                         '        throws DefinitionDecodingException, ManagedObjectDecodingException,&#xa;',
                         '        ManagedObjectNotFoundException, ConcurrentModificationException,&#xa;',
                         '        AuthorizationException, CommunicationException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-name,'RelationDefinition()).getConfiguration();&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public &lt;M extends ', $java-class-name, 'CfgClient&gt; M create', $java-relation-name, '(&#xa;',
                         '        ManagedObjectDefinition&lt;M, ? extends ', $java-class-name,'Cfg&gt; d, Collection&lt;DefaultBehaviorException&gt; exceptions) {&#xa;',
                         '      return impl.createChild(INSTANCE.get', $java-relation-name,'RelationDefinition(), d, exceptions).getConfiguration();&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, '()&#xa;',
                         '        throws ManagedObjectNotFoundException, ConcurrentModificationException,&#xa;',
                         '        OperationRejectedException, AuthorizationException, CommunicationException {&#xa;',
                         '      impl.removeChild(INSTANCE.get', $java-relation-name,'RelationDefinition());&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:one-to-many">
        <xsl:variable name="plural-name"
          select="adm:one-to-many/@plural-name" />
        <xsl:variable name="java-relation-plural-name">
          <xsl:call-template name="name-to-java">
            <xsl:with-param name="value" select="$plural-name" />
          </xsl:call-template>
        </xsl:variable>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public String[] list', $java-relation-plural-name, '() throws ConcurrentModificationException,&#xa;',
                         '        AuthorizationException, CommunicationException {&#xa;',
                         '      return impl.listChildren(INSTANCE.get', $java-relation-plural-name,'RelationDefinition());&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'CfgClient get', $java-relation-name, '(String name)&#xa;',
                         '        throws DefinitionDecodingException, ManagedObjectDecodingException,&#xa;',
                         '        ManagedObjectNotFoundException, ConcurrentModificationException,&#xa;',
                         '        AuthorizationException, CommunicationException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-plural-name,'RelationDefinition(), name).getConfiguration();&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:choose>
          <xsl:when test="string(adm:one-to-many/@unique) != 'true'">
            <xsl:value-of
              select="concat('    /**&#xa;',
                             '     * {@inheritDoc}&#xa;',
                             '     */&#xa;',
                             '    public &lt;M extends ', $java-class-name, 'CfgClient&gt; M create', $java-relation-name, '(&#xa;',
                             '        ManagedObjectDefinition&lt;M, ? extends ', $java-class-name,'Cfg&gt; d, String name, Collection&lt;DefaultBehaviorException&gt; exceptions) throws IllegalManagedObjectNameException {&#xa;',
                             '      return impl.createChild(INSTANCE.get', $java-relation-plural-name,'RelationDefinition(), d, name, exceptions).getConfiguration();&#xa;',
                             '    }&#xa;')" />
          </xsl:when>
          <xsl:when test="string(adm:one-to-many/@unique) = 'true'">
            <!--  Unique one-to-many children are named implicitly by their definition -->
            <xsl:value-of
              select="concat('    /**&#xa;',
                             '     * {@inheritDoc}&#xa;',
                             '     */&#xa;',
                             '    public &lt;M extends ', $java-class-name, 'CfgClient&gt; M create', $java-relation-name, '(&#xa;',
                             '        ManagedObjectDefinition&lt;M, ? extends ', $java-class-name,'Cfg&gt; d, Collection&lt;DefaultBehaviorException&gt; exceptions) {&#xa;',
                             '      return impl.createChild(INSTANCE.get', $java-relation-plural-name,'RelationDefinition(), d, exceptions).getConfiguration();&#xa;',
                             '    }&#xa;')" />
          </xsl:when>
        </xsl:choose>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, '(String name)&#xa;',
                         '        throws ManagedObjectNotFoundException, ConcurrentModificationException,&#xa;',
                         '        OperationRejectedException, AuthorizationException, CommunicationException {&#xa;',
                         '      impl.removeChild(INSTANCE.get', $java-relation-plural-name,'RelationDefinition(), name);&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Unknown relation type &quot;', local-name(*), '&quot; in relation &quot;', $name, '&quot;.')" />
        </xsl:message>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <!--
    Generate server relation methods.
  -->
  <xsl:template name="generate-server-relation-methods">
    <xsl:variable name="name" select="@name" />
    <xsl:variable name="java-relation-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="$name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="java-class-name">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="@managed-object-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:choose>
      <xsl:when test="adm:one-to-one">
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'Cfg get',
                         $java-relation-name, '() throws ConfigException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-name, 'RelationDefinition()).getConfiguration();&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:one-to-zero-or-one">
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public boolean has',
                         $java-relation-name, '() {&#xa;',
                         '      return impl.hasChild(INSTANCE.get', $java-relation-name, 'RelationDefinition());&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'Cfg get',
                         $java-relation-name, '() throws ConfigException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-name, 'RelationDefinition()).getConfiguration();&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void add', $java-relation-name, 'AddListener(&#xa;',
                         '        ConfigurationAddListener&lt;', $java-class-name,'Cfg&gt; listener) throws ConfigException {&#xa;',
                         '      impl.registerAddListener(INSTANCE.get', $java-relation-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, 'AddListener(&#xa;',
                         '        ConfigurationAddListener&lt;', $java-class-name,'Cfg&gt; listener) {&#xa;',
                         '      impl.deregisterAddListener(INSTANCE.get', $java-relation-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void add', $java-relation-name, 'DeleteListener(&#xa;',
                         '        ConfigurationDeleteListener&lt;', $java-class-name,'Cfg&gt; listener) throws ConfigException {&#xa;',
                         '      impl.registerDeleteListener(INSTANCE.get', $java-relation-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, 'DeleteListener(&#xa;',
                         '        ConfigurationDeleteListener&lt;', $java-class-name,'Cfg&gt; listener) {&#xa;',
                         '      impl.deregisterDeleteListener(INSTANCE.get', $java-relation-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:when test="adm:one-to-many">
        <xsl:variable name="plural-name"
          select="adm:one-to-many/@plural-name" />
        <xsl:variable name="java-relation-plural-name">
          <xsl:call-template name="name-to-java">
            <xsl:with-param name="value" select="$plural-name" />
          </xsl:call-template>
        </xsl:variable>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public String[] list',
                         $java-relation-plural-name, '() {&#xa;',
                         '      return impl.listChildren(INSTANCE.get', $java-relation-plural-name,'RelationDefinition());&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public ', $java-class-name, 'Cfg get',
                         $java-relation-name, '(String name) throws ConfigException {&#xa;',
                         '      return impl.getChild(INSTANCE.get', $java-relation-plural-name, 'RelationDefinition(), name).getConfiguration();&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void add', $java-relation-name, 'AddListener(&#xa;',
                         '        ConfigurationAddListener&lt;', $java-class-name,'Cfg&gt; listener) throws ConfigException {&#xa;',
                         '      impl.registerAddListener(INSTANCE.get', $java-relation-plural-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, 'AddListener(&#xa;',
                         '        ConfigurationAddListener&lt;', $java-class-name,'Cfg&gt; listener) {&#xa;',
                         '      impl.deregisterAddListener(INSTANCE.get', $java-relation-plural-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void add', $java-relation-name, 'DeleteListener(&#xa;',
                         '        ConfigurationDeleteListener&lt;', $java-class-name,'Cfg&gt; listener) throws ConfigException {&#xa;',
                         '      impl.registerDeleteListener(INSTANCE.get', $java-relation-plural-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:text>&#xa;</xsl:text>
        <xsl:value-of
          select="concat('    /**&#xa;',
                         '     * {@inheritDoc}&#xa;',
                         '     */&#xa;',
                         '    public void remove', $java-relation-name, 'DeleteListener(&#xa;',
                         '        ConfigurationDeleteListener&lt;', $java-class-name,'Cfg&gt; listener) {&#xa;',
                         '      impl.deregisterDeleteListener(INSTANCE.get', $java-relation-plural-name, 'RelationDefinition(), listener);&#xa;',
                         '    }&#xa;')" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('Unknown relation type &quot;', local-name(*), '&quot; in relation &quot;', $name, '&quot;.')" />
        </xsl:message>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  <!--
    Generate change listener registration methods.
  -->
  <xsl:template name="generate-change-listener">
    <!--
      Process this managed object.
    -->
    <xsl:variable name="top-name"
      select="$this/adm:profile[@name='preprocessor']/admpp:parent-managed-object[last()]/@name" />
    <xsl:call-template name="generate-change-listener-help">
      <xsl:with-param name="top-name" select="$top-name" />
      <xsl:with-param name="name" select="$this-name" />
    </xsl:call-template>
    <!--
      Process parent hierarchy.
    -->
    <xsl:for-each
      select="$this/adm:profile[@name='preprocessor']/admpp:parent-managed-object">
      <xsl:call-template name="generate-change-listener-help">
        <xsl:with-param name="top-name" select="$top-name" />
        <xsl:with-param name="name" select="@name" />
      </xsl:call-template>
    </xsl:for-each>
  </xsl:template>
  <!--
    Generate a single set of change listener registration methods.
  -->
  <xsl:template name="generate-change-listener-help">
    <xsl:param name="top-name" select="/.." />
    <xsl:param name="name" select="/.." />
    <xsl:variable name="short-name">
      <xsl:choose>
        <xsl:when test="not($top-name) or $top-name = $name">
          <xsl:value-of select="''" />
        </xsl:when>
        <xsl:otherwise>
          <xsl:variable name="top-length"
            select="string-length($top-name)" />
          <xsl:variable name="length" select="string-length($name)" />
          <xsl:variable name="diff" select="$length - $top-length" />
          <xsl:value-of select="substring($name, 1, $diff - 1)" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:variable>
    <xsl:variable name="java-class">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="$name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:variable name="short-java-class">
      <xsl:call-template name="name-to-java">
        <xsl:with-param name="value" select="$short-name" />
      </xsl:call-template>
    </xsl:variable>
    <xsl:value-of
      select="concat('    /**&#xa;',
                     '     * {@inheritDoc}&#xa;',
                     '     */&#xa;')" />
    <xsl:value-of
      select="concat('    public void add', $short-java-class, 'ChangeListener(&#xa;',
                     '        ConfigurationChangeListener&lt;',$java-class,'Cfg&gt; listener) {&#xa;',
                     '      impl.registerChangeListener(listener);&#xa;',
                     '    }&#xa;')" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of
      select="concat('    /**&#xa;',
                     '     * {@inheritDoc}&#xa;',
                     '     */&#xa;')" />
    <xsl:value-of
      select="concat('    public void remove', $short-java-class, 'ChangeListener(&#xa;',
                     '        ConfigurationChangeListener&lt;',$java-class,'Cfg&gt; listener) {&#xa;',
                     '      impl.deregisterChangeListener(listener);&#xa;',
                     '    }&#xa;')" />
  </xsl:template>
  <!--
    Generate import statements for change-listener
  -->
  <xsl:template name="generate-change-listener-import-statements">
    <!--
      Process this managed object.
    -->
    <xsl:element name="import">
      <xsl:value-of
        select="concat($this-package, '.server.', $this-java-class, 'Cfg')" />
    </xsl:element>
    <!--
      Process parent hierarchy.
    -->
    <xsl:for-each
      select="$this/adm:profile[@name='preprocessor']/admpp:parent-managed-object">
      <xsl:variable name="java-class">
        <xsl:call-template name="name-to-java">
          <xsl:with-param name="value" select="@name" />
        </xsl:call-template>
      </xsl:variable>
      <xsl:element name="import">
        <xsl:value-of
          select="concat(@package, '.server.', $java-class, 'Cfg')" />
      </xsl:element>
    </xsl:for-each>
  </xsl:template>
  <!--
    Generate an enumeration for a locally defined enumerated property.
  -->
  <xsl:template name="generate-enumeration">
    <xsl:value-of
      select="concat('  /**&#xa;',
                     '   * Defines the set of permissable values for the &quot;', @name, '&quot; property.&#xa;')" />
    <xsl:if test="adm:synopsis">
      <xsl:value-of select="'   * &lt;p&gt;&#xa;'" />
      <xsl:call-template name="add-java-comment">
        <xsl:with-param name="indent-text" select="'   *'" />
        <xsl:with-param name="content" select="adm:synopsis" />
      </xsl:call-template>
    </xsl:if>
    <xsl:if test="adm:description">
      <xsl:value-of select="'   * &lt;p&gt;&#xa;'" />
      <xsl:call-template name="add-java-comment">
        <xsl:with-param name="indent-text" select="'   *'" />
        <xsl:with-param name="content" select="adm:description" />
      </xsl:call-template>
    </xsl:if>
    <xsl:value-of
      select="concat('   */&#xa;',
                     '  public static enum ')" />
    <xsl:call-template name="name-to-java">
      <xsl:with-param name="value" select="@name" />
    </xsl:call-template>
    <xsl:value-of select="' {&#xa;'" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:for-each select="adm:syntax/adm:enumeration/adm:value">
      <xsl:sort select="@name" />
      <xsl:value-of select="'    /**&#xa;'" />
      <xsl:call-template name="add-java-comment">
        <xsl:with-param name="indent-text" select="'     *'" />
        <xsl:with-param name="content" select="adm:synopsis" />
      </xsl:call-template>
      <xsl:value-of select="'     */&#xa;'" />
      <xsl:value-of select="'    '" />
      <xsl:call-template name="name-to-java-constant">
        <xsl:with-param name="value" select="@name" />
      </xsl:call-template>
      <xsl:value-of select="concat('(&quot;', @name, '&quot;)')" />
      <xsl:choose>
        <xsl:when test="position() != last()">
          <xsl:value-of select="',&#xa;'" />
          <xsl:text>&#xa;</xsl:text>
          <xsl:text>&#xa;</xsl:text>
          <xsl:text>&#xa;</xsl:text>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="';&#xa;'" />
        </xsl:otherwise>
      </xsl:choose>
    </xsl:for-each>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of
      select="'    // String representation of the value.&#xa;'" />
    <xsl:value-of select="'    private final String name;&#xa;'" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of select="'    // Private constructor.&#xa;'" />
    <xsl:value-of select="'    private '" />
    <xsl:call-template name="name-to-java">
      <xsl:with-param name="value" select="@name" />
    </xsl:call-template>
    <xsl:value-of
      select="concat('(String name) { this.name = name; }&#xa;',
                     '&#xa;',
                     '&#xa;',
                     '&#xa;',
                     '    /**&#xa;',
                     '     * {@inheritDoc}&#xa;',
                     '     */&#xa;',
                     '    public String toString() { return name; }&#xa;')" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:value-of select="'  }&#xa;'" />
  </xsl:template>
  <!--
    Main document parsing template.
  -->
  <xsl:template match="/">
    <!--  Perform some initial validation.
    -->
    <xsl:for-each select="$this-all-properties">
      <!--
        Check that all non-mandatory properties have a default behavior.
      -->
      <xsl:if
        test="not(@mandatory='true') and not(adm:default-behavior)">
        <xsl:message terminate="yes">
          <xsl:value-of
            select="concat('No default behavior defined for non-mandatory property &quot;', @name,
                         '&quot;.')" />
        </xsl:message>
      </xsl:if>
      <!--
        Check that all advanced properties conform to one of
        the following rules:

        * is mandatory and has a defined default value(s)
        * is mandatory and is part of an advanced managed object
        * is mandatory and is part of an abstract managed object
        * is not mandatory
      -->
      <xsl:choose>
        <xsl:when test="$this-is-advanced">
          <!--  OK  -->
        </xsl:when>
        <xsl:when test="$this-is-abstract">
          <!--  OK  -->
        </xsl:when>
        <xsl:when test="@advanced='true' and @mandatory='true'">
          <xsl:choose>
            <xsl:when test="adm:default-behavior/adm:defined">
              <!--  OK  -->
            </xsl:when>
            <xsl:when test="adm:default-behavior/adm:inherited">
              <!--  OK  -->
            </xsl:when>
            <xsl:otherwise>
              <xsl:message terminate="yes">
                <xsl:value-of
                  select="concat('Advanced property &quot;', @name,
                         '&quot; must have defined or inherited default values.')" />
              </xsl:message>
            </xsl:otherwise>
          </xsl:choose>
        </xsl:when>
      </xsl:choose>
    </xsl:for-each>
    <!--
      Now generate the definition.
    -->
    <xsl:call-template name="copyright-notice" />
    <xsl:value-of
      select="concat('package ', $this-package, '.meta;&#xa;')" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:call-template name="generate-import-statements">
      <xsl:with-param name="imports">
        <xsl:if test="not(boolean($this/@extends))">
          <import>org.opends.server.admin.TopCfgDefn</import>
        </xsl:if>
        <xsl:if test="$this/adm:constraint">
          <import>org.opends.server.admin.GenericConstraint</import>
          <import>org.opends.server.admin.condition.Conditions</import>
        </xsl:if>
        <xsl:if
          test="$this-local-properties[@multi-valued='true' or
                                       @read-only='true' or
                                       @monitoring='true' or
                                       @hidden='true' or
                                       @advanced='true' or
                                       @mandatory='true']">
          <import>org.opends.server.admin.PropertyOption</import>
        </xsl:if>
        <xsl:if test="$this-local-properties">
          <import>org.opends.server.admin.AdministratorAction</import>
        </xsl:if>
        <xsl:if test="$this/adm:tag-definition or $this/adm:tag">
          <import>org.opends.server.admin.Tag</import>
        </xsl:if>
        <xsl:if
          test="$this-local-properties[adm:default-behavior/adm:undefined or not(adm:default-behavior)]">
          <import>
            org.opends.server.admin.UndefinedDefaultBehaviorProvider
          </import>
        </xsl:if>
        <xsl:if
          test="$this-local-properties/adm:default-behavior/adm:alias">
          <import>
            org.opends.server.admin.AliasDefaultBehaviorProvider
          </import>
        </xsl:if>
        <xsl:if
          test="$this-local-properties/adm:default-behavior/adm:inherited/adm:absolute">
          <import>
            org.opends.server.admin.AbsoluteInheritedDefaultBehaviorProvider
          </import>
        </xsl:if>
        <xsl:if
          test="$this-local-properties/adm:default-behavior/adm:inherited/adm:relative">
          <import>
            org.opends.server.admin.RelativeInheritedDefaultBehaviorProvider
          </import>
          <xsl:for-each
            select="$this-local-properties/adm:default-behavior/adm:inherited/adm:relative">
            <xsl:if test="@managed-object-package != $this-package">
              <xsl:variable name="java-class-name">
                <xsl:call-template name="name-to-java">
                  <xsl:with-param name="value"
                    select="@managed-object-name" />
                </xsl:call-template>
              </xsl:variable>
              <xsl:element name="import">
                <xsl:value-of
                  select="concat(@managed-object-package, '.meta.', $java-class-name, 'CfgDefn')" />
              </xsl:element>
            </xsl:if>
          </xsl:for-each>
        </xsl:if>
        <xsl:if
          test="$this-local-properties/adm:default-behavior/adm:defined">
          <import>
            org.opends.server.admin.DefinedDefaultBehaviorProvider
          </import>
          <import>
            org.opends.server.admin.DefaultBehaviorProvider
          </import>
        </xsl:if>
        <xsl:element name="import">
          <xsl:value-of
            select="concat($this-package, '.client.', $this-java-class, 'CfgClient')" />
        </xsl:element>
        <xsl:element name="import">
          <xsl:value-of
            select="concat($this-package, '.server.', $this-java-class, 'Cfg')" />
        </xsl:element>
        <xsl:for-each select="$this-inherited-properties">
          <xsl:call-template name="get-property-java-imports">
            <xsl:with-param name="interface" select="'server'" />
          </xsl:call-template>
        </xsl:for-each>
        <xsl:for-each select="$this-all-properties">
          <xsl:call-template
            name="get-property-definition-java-imports" />
        </xsl:for-each>
        <xsl:for-each select="$this-all-relations">
          <xsl:variable name="java-class-name">
            <xsl:call-template name="name-to-java">
              <xsl:with-param name="value"
                select="@managed-object-name" />
            </xsl:call-template>
          </xsl:variable>
          <xsl:element name="import">
            <xsl:value-of
              select="concat(@managed-object-package, '.client.', $java-class-name, 'CfgClient')" />
          </xsl:element>
          <xsl:element name="import">
            <xsl:value-of
              select="concat(@managed-object-package, '.server.', $java-class-name, 'Cfg')" />
          </xsl:element>
        </xsl:for-each>
        <xsl:if
          test="$this-local-relations/*/adm:default-managed-object">
          <import>org.opends.server.admin.DefaultManagedObject</import>
        </xsl:if>
        <xsl:for-each
          select="$this-local-relations/*/adm:default-managed-object">
          <xsl:variable name="java-class-name">
            <xsl:call-template name="name-to-java">
              <xsl:with-param name="value"
                select="@managed-object-name" />
            </xsl:call-template>
          </xsl:variable>
          <xsl:element name="import">
            <xsl:value-of
              select="concat(@managed-object-package, '.client.', $java-class-name, 'CfgClient')" />
          </xsl:element>
          <xsl:element name="import">
            <xsl:value-of
              select="concat(@managed-object-package, '.server.', $java-class-name, 'Cfg')" />
          </xsl:element>
          <xsl:element name="import">
            <xsl:value-of
              select="concat(@managed-object-package, '.meta.', $java-class-name, 'CfgDefn')" />
          </xsl:element>
        </xsl:for-each>
        <xsl:if
          test="$this-local-relations[@advanced='true' or @hidden='true']">
          <import>org.opends.server.admin.RelationOption</import>
        </xsl:if>
        <xsl:if test="$this-is-hidden or $this-is-advanced">
          <import>org.opends.server.admin.ManagedObjectOption</import>
        </xsl:if>
        <xsl:if test="$this-all-relations/adm:one-to-many[not(@unique = 'true')]">
          <import>
            org.opends.server.admin.InstantiableRelationDefinition
          </import>
        </xsl:if>
        <xsl:if test="$this-all-relations/adm:one-to-many[@unique = 'true']">
          <import>
            org.opends.server.admin.SetRelationDefinition
          </import>
        </xsl:if>
        <xsl:if test="$this-all-relations/adm:one-to-zero-or-one">
          <import>
            org.opends.server.admin.OptionalRelationDefinition
          </import>
        </xsl:if>
        <xsl:if test="$this-all-relations/adm:one-to-one">
          <import>
            org.opends.server.admin.SingletonRelationDefinition
          </import>
        </xsl:if>
        <xsl:choose>
          <xsl:when test="$this-is-abstract">
            <import>
              org.opends.server.admin.AbstractManagedObjectDefinition
            </import>
          </xsl:when>
          <xsl:otherwise>
            <import>
              org.opends.server.admin.ManagedObjectDefinition
            </import>
            <import>org.opends.server.admin.PropertyProvider</import>
            <import>
              org.opends.server.admin.client.MissingMandatoryPropertiesException
            </import>
            <import>
              org.opends.server.admin.ManagedObjectAlreadyExistsException
            </import>
            <import>
              org.opends.server.admin.client.AuthorizationException
            </import>
            <import>
              org.opends.server.admin.client.CommunicationException
            </import>
            <import>
              org.opends.server.admin.client.ConcurrentModificationException
            </import>
            <import>
              org.opends.server.admin.client.OperationRejectedException
            </import>
            <import>
              org.opends.server.admin.client.ManagedObject
            </import>
            <import>
              org.opends.server.admin.server.ServerManagedObject
            </import>
            <xsl:if test="not($this-is-root)">
              <import>
                org.opends.server.admin.server.ConfigurationChangeListener
              </import>
              <xsl:call-template
                name="generate-change-listener-import-statements" />
            </xsl:if>
            <import>org.opends.server.types.DN</import>
            <xsl:if test="$this-all-relations">
              <import>
                org.opends.server.admin.DefinitionDecodingException
              </import>
              <import>
                org.opends.server.admin.ManagedObjectNotFoundException
              </import>
              <import>
                org.opends.server.admin.client.ManagedObjectDecodingException
              </import>
            </xsl:if>
            <xsl:if test="$this-all-relations/adm:one-to-many">
              <import>java.util.Collection</import>
              <xsl:if test="$this-all-relations/adm:one-to-many[not(@unique = 'true')]">
                <import>
                  org.opends.server.admin.client.IllegalManagedObjectNameException
                </import>
              </xsl:if>
              <import>
                org.opends.server.admin.DefaultBehaviorException
              </import>
              <import>
                org.opends.server.admin.server.ConfigurationAddListener
              </import>
              <import>
                org.opends.server.admin.server.ConfigurationDeleteListener
              </import>
              <import>org.opends.server.config.ConfigException</import>
            </xsl:if>
            <xsl:if test="$this-all-relations/adm:one-to-zero-or-one">
              <import>java.util.Collection</import>
              <import>
                org.opends.server.admin.DefaultBehaviorException
              </import>
              <import>
                org.opends.server.admin.server.ConfigurationAddListener
              </import>
              <import>
                org.opends.server.admin.server.ConfigurationDeleteListener
              </import>
              <import>org.opends.server.config.ConfigException</import>
            </xsl:if>
            <xsl:if test="$this-all-relations/adm:one-to-one">
              <import>org.opends.server.config.ConfigException</import>
            </xsl:if>
            <xsl:if test="$this-all-properties[@multi-valued='true']">
              <import>java.util.SortedSet</import>
              <import>java.util.Collection</import>
            </xsl:if>
            <xsl:if test="$this-all-properties[@read-only='true']">
              <import>
                org.opends.server.admin.PropertyIsReadOnlyException
              </import>
            </xsl:if>
          </xsl:otherwise>
        </xsl:choose>
        <xsl:if test="$this/@extends">
          <xsl:if test="$parent-package != $this-package">
            <xsl:element name="import">
              <xsl:value-of
                select="concat($parent-package, '.meta.', $parent-java-class, 'CfgDefn')" />
            </xsl:element>
          </xsl:if>
        </xsl:if>
      </xsl:with-param>
    </xsl:call-template>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:text>&#xa;</xsl:text>
    <xsl:call-template name="generate-meta-class-declaration" />
    <xsl:text>&#xa;</xsl:text>
    <xsl:call-template name="generate-meta-class-body" />
    <xsl:text>}&#xa;</xsl:text>
  </xsl:template>
</xsl:stylesheet>